home *** CD-ROM | disk | FTP | other *** search
/ CD ROM Paradise Collection 4 / CD ROM Paradise Collection 4 1995 Nov.iso / comms / dis_pkt9.zip / DIS_PKT9.ASM next >
Assembly Source File  |  1991-11-02  |  68KB  |  2,295 lines
  1.     TITLE    DIS_PKT
  2.  
  3. ; DIS_PKT.ASM - Adapter provides Packet Driver v1.09 interface over NDIS.
  4. ; Version 1.07  18 May 1991  by Joe R. Doupnik, Utah State Univ.
  5. ; Version 1.08  9 Aug 1991 by Dan Lanciani, ddl@harvard.harvard.edu
  6. ; Version 1.09  3 Nov 1991 by Joe R. Doupnik, Utah State Univ.
  7. ; Copyright (C) 1988 - 1991 FTP Software, Inc.
  8. ;
  9. ; This unmodified source file and it's executable form may be used and
  10. ; redistributed freely.  The source may be modified, and the source or
  11. ; executable versions built from the modified source may be used and
  12. ; redistributed, provided that this notice and the copyright displayed by
  13. ; the exectuable remain intact, and provided that the executable displays
  14. ; an additional message indicating that it has been modified, and by whom.
  15. ;
  16. ; FTP Software Inc. releases this software "as is", with no express or
  17. ; implied warranty, including, but not limited to, the implied warranties
  18. ; of merchantability and fitness for a particular purpose.
  19. ;
  20. ; USE AT YOUR OWN RISK.
  21. ;
  22. ;
  23. ; To build, using Microsoft MASM 5 or later, LINK 3.64 or later, and EXE2BIN:
  24. ;
  25. ; masm dis_pkt;
  26. ; link dis_pkt;
  27. ; exe2bin dis_pkt.exe dis_pkt.dos
  28. ; del dis_pkt.exe
  29. ; del dis_pkt.obj
  30. ;
  31. ;
  32. ;What DIS_PKT.DOS does: It provides an Ethernet or a Token Ring Packet Driver
  33. ;interface to programs built to operate over Packet Drivers. It talks
  34. ;to NDIS (3Com/Microsoft) instead of to a lan board directly. It shares
  35. ;the board with NDIS users. We call this a "shim", sitting between the
  36. ;normal applications program (NetWare shells, TCP/IP, etc) and the more
  37. ;hardware specific portions (NDIS in this case).
  38. ;
  39. ;    Packet Driver flavored applications    NDIS flavored applications
  40. ;        ||                    ||
  41. ;        -------------                ||
  42. ;        |  DIS_PKT  |                ||
  43. ;        -------------                ||
  44. ;        ||                    ||
  45. ;        ------------------------------------------
  46. ;        |           main module              |
  47. ;        |   NDIS    ........................      |
  48. ;        |        board specific driver(s)      |
  49. ;        -------------------------------------------
  50. ;                  ||
  51. ;            --------------------------------
  52. ;            | Ethernet/Token Ring board(s)    |
  53. ;            --------------------------------
  54. ;                  ||
  55. ;        =================================== Ethernet/Token Ring wire
  56. ;        
  57. ;
  58. ;First sample PROTOCOL.INI file:
  59. ;
  60. ;[protocol manager]
  61. ;    drivername = PROTMAN$
  62. ;
  63. ;[pktdrv]            <-- name of this driver entry
  64. ;  drivername = pktdrv$        <-- formal driver name
  65. ;  bindings = wd8003xmac    <-- use your board's NDIS driver here
  66. ;  intvec = 0x60        <-- Packet Driver Int, 60h..7fh
  67. ;  chainvec = 0x66        <-- post-EOI processing interrupt, unused
  68. ;  novell = y            <-- Optional, if present and y(es) then
  69. ;                    convert between old Novell 802.3 pkts
  70. ;                    on the wire and Type 8137 for the app.
  71. ;                    Omitting this line or using any other
  72. ;                    response turns off the conversion; 
  73. ;                    default is no conversion.
  74. ;
  75. ;[attiso]
  76. ;  drivername = ATTISO$        <-- Another NDIS client
  77. ;  bindings = wd8003xmac    <-- bound to the same harware driver
  78. ;  nsess = 5
  79. ;  ncmds = 14
  80. ;  use_emm = n
  81. ;
  82. ;Western Digital EtherCard PLUS Family Adapter    <-- Ethernet board
  83. ;[wd8003xmac]                    <-- its ndis driver
  84. ;    drivername = MACWD$
  85. ;    irq = 7
  86. ;    ramaddress = 0xCA00
  87. ;    iobase = 0x280
  88. ;    receivebufsize = 1536    <-- make this a full Ethernet pkt
  89. ;
  90. ;
  91. ;
  92. ;
  93. ;Sample section of CONFIG.SYS (StarGROUP material is not required):
  94. ;
  95. ;device=c:\lanman\protman.sys /i:c:\lanman    <-- must be first
  96. ;device=c:\lanman\macwd.dos            <-- WD8003E driver
  97. ;device=c:\lanman\dis_pkt.dos            <-- Pkt Driver (this program)
  98. ;device=c:\lanman.dos\drivers\attload.dos /Y    <-- StarGROUP NDIS 
  99. ;device=c:\lanman.dos\drivers\attiso\attiso.dos    <-- StarGROUP NDIS
  100. ;device=c:\qemm\loadhi.sys /r:1 e:\pctcp\ifcust.sys  <-- PC/TCP stuff
  101. ;device=c:\qemm\loadhi.sys /r:4 e:\pctcp\ipcust.sys  <-- etc
  102. ;
  103. ;
  104. ; A second, more elaborate example, with names easier to type. We start with
  105. ;file PROTOCOL.INI. Note that semicolons start comment lines.
  106. ;
  107. ;; This is a sample protocol.ini file listing three Ethernet boards:
  108. ;;    attcsma.dos is an AT&T StarLAN 10 EN100
  109. ;;    elnkii.dos  is a 3Com 3C503
  110. ;;    wd8003.dos  is a Western Digital WD8003E
  111. ;; Only one board will be selected but the other two are present.
  112. ;
  113. ;[protocol manager]
  114. ;    drivername = PROTMAN$
  115. ;
  116. ;; Packet Driver protocol users tie in here
  117. ;[pktdrv]
  118. ;    drivername = pktdrv$
  119. ;    bindings = attcsma
  120. ;;    bindings= elnkii
  121. ;;    bindings = wd8003
  122. ;    intvec = 0x60
  123. ;;    chainvec = 0x66
  124. ;    novell = no        ; do not convert packet types this time
  125. ;
  126. ;; AT&T StarGROUP protocol stack ties in here via name ATTISO$
  127. ;[attiso]
  128. ;    drivername = ATTISO$
  129. ;    bindings = attcsma
  130. ;;    bindings = elnkii
  131. ;;    bindings = wd8003
  132. ;    nsess = 5
  133. ;    ncmds = 14
  134. ;    use_emm = n
  135. ;
  136. ;;Western Digital EtherCard PLUS Family Adapter, WD8003E in this case
  137. ;[wd8003]
  138. ;    drivername = MACWD$
  139. ;    irq = 7
  140. ;    ramaddress = 0xCA00
  141. ;    iobase = 0x280
  142. ;    receivebufsize = 1536
  143. ;;    maxtransmits = 6
  144. ;;    receivebuffers = 6
  145. ;;    receivechains = 6
  146. ;
  147. ;; 3Com Etherlink II, 3C503
  148. ;[elnkii]
  149. ;    drivername = ELNKII$
  150. ;    ioaddress = 0x350
  151. ;    interrupt = 5
  152. ;    transceiver = onboard
  153. ;    maxtransmits = 12
  154. ;    xmitbufs = 1
  155. ;
  156. ;; AT&T StarLAN 10 EN100
  157. ;[attcsma]
  158. ;    drivername = ATTCSMA$
  159. ;    board_type = 2
  160. ;    irq = 2
  161. ;    ioaddr = 0x360
  162. ;    daram = 0xD000
  163. ;
  164. ;; End of file protocol.ini
  165. ;
  166. ;Fragment of config.sys for the second example. Note three .dos board drivers.
  167. ;
  168. ;device=c:\system\ramdrive.sys 1024 512 128 /E
  169. ;device=c:\lanman\protman.sys /i:c:\lanman.dos\drivers\star10en
  170. ;device=c:\lanman\attcsma.dos
  171. ;device=c:\lanman\elnkii.sys
  172. ;device=c:\lanman\macwd.dos
  173. ;device=c:\lanman\dis_pkt.dos
  174. ;device=c:\lanman.dos\drivers\attload.dos /Y
  175. ;device=c:\lanman.dos\drivers\attiso\attiso.dos
  176. ;device=c:\qemm\loadhi.sys /r:1 e:\pctcp\ifcust.sys
  177. ;device=c:\qemm\loadhi.sys /r:4 e:\pctcp\ipcust.sys
  178. ;device=c:\qemm\loadhi.sys /r:4 c:\netdev.sys
  179. ;shell=c:\command.com  /p /e:800
  180. ;
  181. ;It seems to be necessary to run NETBIND.EXE to get all this to be active.
  182. ;
  183.  
  184. ; 
  185. ; Edit History
  186. ; 06-Jul-89    WJR    Changed interface flags in LDT to 2 per Norsk Data
  187. ;             (may make vector binding work). Changed receive to
  188. ;             allocate buffer for frame size instead of lookahead
  189. ;             value. (This will fail miserably if the frame size
  190. ;             is unknown at upcall time; such is life.) Changed
  191. ;             SetPacketFilter to use module ID instead of dummy.
  192. ; 11-Sep-89    jbvb    Clean up, add 1.09 functionality.
  193. ; 12-Sep-89    jbvb    Don't do interrupt if vector contents are 0.
  194. ; 14-Sep-89     wjr    Changed frame_rejected to frame_not_recognized to make
  195. ;             vectored operation work.  Changed send_pkt to use
  196. ;             drv_cct.mod_id. Tried using 0 as protocol id in open
  197. ;             adapter call.  Changed device name to pktdrv$,
  198. ;             flushed open adapter not supported message.
  199. ; 15-Sep-89    wjr    Changed open adapter back to CS since 0 broke it.
  200. ; 24-Oct-89    wjr    Changed FRAME_NOT_RECOGNIZED from 4 to 3
  201. ; 07-Feb-90    wjr    Added push and pop SI to rcv_chn & rcv_lah.
  202. ; 02-Apr-90    wjr    Fixed xmt_chn to properly check for request queued
  203. ; 03-Apr-90    wjr    Given changed TCP, treat REQUEST_QUEUED as success.
  204. ; 06-Apr-90    jbvb    Update patch level to 2.
  205. ; 23-Apr-90    jbvb    Don't trash BP, free init code, fix comments.
  206. ; 25-Apr-90    jbvb    Support "extended" calls: get/set_rcv_mode,
  207. ;             get_statistics will suffice for LW.
  208. ; 26-Apr-90    jbvb    Support "match all" on typelen == 0.
  209. ; 05-Jun-90    jbvb    Fix stack bug in "match all" handling in access_type,
  210. ;             pass valid CX on 2nd receiver() upcall, version 5.
  211. ; 13-Jun-90    jbvb    Write basic set_address() code, but comment it out
  212. ;             because NDIS may require a CloseAdapter first in
  213. ;             order for it to work.  Not worth it to me.
  214. ; 27-Jul-90    jbvb    Copyright, build instructions, release v1.05.
  215. ; 24-Mar-91    jrd    Rewrite great chunks to straighen out stack and DS
  216. ;            addressing. This now works with Novell IPX/NETn
  217. ;            and Netwatch (together as a matter of fact) and
  218. ;            with PC/TCP from FTP Inc. Version to 1.06.
  219. ;            Joe R. Doupnik,    jrd@cc.usu.edu, Utah State Univ.
  220. ; 30-Mar-91    jrd    Allow 10 byte TYPE idents to pick out packets,
  221. ;            more cleanups, more needed. Promiscuous mode put last.
  222. ;            Allow 20 handles. Works fine with (NetWare+PC/TCP+
  223. ;            Netwatch) Pkt Drvr + Lan Man going simulanteously.
  224. ;            Works with Clarkson issued Packet Driver utilities.
  225. ; 18-May-91    jrd    Add filtering of packet addresses if running in
  226. ;            promiscuous mode, add get current Ethernet address
  227. ;            function to aid filtering, add receive mode indicator
  228. ;            for each handle, correct error in snd_def initing.
  229. ;            Correct problem with receive lookahead addressing.
  230. ;            Compensate for 3Com drivers not preserving regs.
  231. ;            Bump up NDIS tables to v2. Dis_pkt version to 1.07.
  232. ; 09-Aug-91    ddl    802.5, 802.3 support; default binding; overwrite fix
  233. ; 03-Nov-91    jrd    Add keyword NOVELL to PROTOCOL.INI to convert between
  234. ;            old Novell 802.3 packets on the wire to 8137 for the
  235. ;            applications program. Convert if the line is present
  236. ;            and the value is y(es). Small cleanups.
  237.     PAGE ,80
  238.  
  239. EOL    EQU    <13, 10, '$'>
  240. LF    =    10
  241. CR    =    13
  242. EOS    =    '$'
  243. DOS    equ    21h
  244. prstr    equ    9
  245. fopen    equ    3dh
  246. fclose    equ    3eh
  247. ioctl    equ    44h
  248.  
  249. MSG    MACRO    TEXT
  250.     PUSH    DX            ;; save DX across call
  251.     push    ax
  252.     push    ds
  253.     mov    ax,cs
  254.     mov    ds,ax
  255.     MOV    DX,OFFSET TEXT        ;; point to message
  256.     mov    ah,prstr        ; display dollar terinated string
  257.     int    dos
  258.     pop    ds
  259.     pop    ax
  260.     POP    DX
  261.     ENDM
  262.  
  263. ; DOS request header offsets
  264.  
  265. command    =    2
  266. status    =    3
  267. bpb    =    18
  268. end_off    =    14
  269. end_seg =    16
  270.  
  271. ; NDIS General Request codes
  272.  
  273. INIT_DIAG    equ    1
  274. READ_ERR_LOG    equ    2
  275. SET_STA_ADDR    equ    3
  276. OPEN_ADAPTER    equ    4
  277. CLOSE_ADAPTER    equ    5
  278. RESET_MAC    equ    6
  279. SET_PKT_FLT    equ    7
  280. ADD_MULT_ADDR    equ    8
  281. DEL_MULT_ADDR    equ    9
  282. UPDATE_STATS    equ    10
  283. CLEAR_STATS    equ    11
  284. INTERRUPT_ME    equ    12
  285. SET_FUNC_ADDR    equ    13
  286. SET_LOOKAHEAD    equ    14
  287.  
  288. ADDR_NONE    EQU    0    ; NDIS Receiver modes: disabled
  289. ADDR_MULT    EQU    1    ; Receive packets for my address & multicast
  290. ADDR_BRD    EQU    2    ; Receive broadcast packets
  291. ADDR_PROM    EQU    4    ; Receive all packets (promiscuous mode)
  292. ADDR_SRCRT    EQU    8    ; Receive all source-routed packets
  293.  
  294. ; Protocol to MAC return codes
  295.  
  296. SUCCESS            EQU    0
  297. REQUEST_QUEUED        EQU    2
  298. FRAME_NOT_RECOGNIZED    EQU    3
  299. NOT_SUPPORTED        EQU    9
  300. GENERAL_FAILURE        EQU    0FFH
  301.  
  302. ; NDIS-related structure definitions
  303.  
  304. cct_def    struc
  305.     dw    64        ; Size of common characteristics table (cct)
  306.     dw    0        ; Level of cct (zero this version)
  307.     dw    0        ; Level of service-specific subtables
  308.     db    2        ; Major module version (2 BCD digits)
  309.     db    0        ; Minor module version (2 BCD digits)
  310.     dd    2        ; Module function flags
  311.     db    'PKTDRV$', 9 dup (0) ; Module name, 16 byte ASCIIZ format
  312.     db    4        ; Protocol level at upper boundary of module
  313.     db    0        ; type of interface at upper module boundary
  314.     db    1        ; protocol level at lower boundary of module
  315.     db    1        ; type of interface at lower module boundary
  316. mod_id    dw    -1        ; module ID filled in by Protocol Manager
  317. mod_ds    dw    0        ; module DS
  318. system    dd    0        ; system request dispatch entry point
  319. sscp    dd    0        ; pointer to service-specific characteristics
  320. sssp    dd    0        ; pointer to service-specific status
  321. udtp    dd    0        ; pointer to upper dispatch table
  322. ldtp    dd    0        ; pointer to lower dispatch table
  323.     dd    0        ; reserved (must be NULL)
  324.     dd    0        ; reserved (must be NULL)
  325. cct_def    ends
  326.  
  327. ssc_def    struc
  328.     dw    94        ; length of MAC service-specific 
  329.                 ; characteristics table (ssc)
  330. mtype    db    16 dup (0)    ; type name of MAC, ASCIIZ format
  331.     dw    0        ; length of station addresses in bytes
  332.     db    16 dup (0)    ; permanent station address
  333. cur_add    db    16 dup (0)    ; current station address
  334.     dd    0        ; current functional address of adapter
  335.     dd    0        ; multicast address list
  336.     dd    0        ; link speed
  337. svc_1    dw    0        ; service flags
  338. svc_2    dw    0        ; service flags
  339. maxfram    dw    0        ; max frame size both sent and recv
  340.     dd    0        ; total transmission buffer cap in driver
  341.     dw    0        ; transmission buffer allocation block size
  342.     dd    0        ; total reception buffer cap in driver
  343.     dw    0        ; reception buffer allocation block size
  344.     db    3 dup (0)    ; IEEE vendor code (OUI)
  345.     db    0        ; vendor adapter code
  346.     dd    0        ; vendor adapter description pointer
  347.     dw    0        ; IRQ of adapter (NDIS v2)
  348.     dw    0        ; transmit queue depth (NDIS v2)
  349. ssc_def    ends
  350.  
  351. sss_def    struc
  352.     dw    0        ; length of status table
  353.     dd    0        ; date/time of last diagnostics 
  354.     dd    0        ; MAC status
  355.     dw    0        ; current packet filter
  356.     dd    0        ; pointer to media specific statistics table
  357.     dd    0        ; date/time of last ClearStatistics call
  358. r_tot    dd    0        ; total frames received
  359. r_crc    dd    0        ; frames with CRC error
  360. rb_tot    dd    0        ; total bytes received
  361. r_drop    dd    0        ; frames discarded - no buffer space
  362. r_mult    dd    0        ; multicast frames received
  363. r_bro    dd    0        ; broadcast frames received
  364. r_err    dd    0        ; frames received with errors
  365. r_big    dd    0        ; frames exceeding maximum size
  366. r_runt    dd    0        ; frames smaller than minimum size
  367. rb_mul    dd    0        ; multicast bytes received
  368. rb_bro    dd    0        ; broadcast bytes received
  369. r_hwer    dd    0        ; frames discarded - hardware error
  370. x_tot    dd    0        ; total frames transmitted
  371. xb_tot    dd    0        ; total bytes transmitted
  372. x_mul    dd    0        ; multicast frames transmitted
  373. x_bro    dd    0        ; broadcast frames transmitted
  374. xb_bro    dd    0        ; broadcast bytes transmitted
  375. xb_mul    dd    0        ; multicast bytes transmitted
  376. x_tmo    dd    0        ; frames not transmitted - time-out
  377. x_hwer    dd    0        ; frames not transmitted - hardware error
  378. sss_def    ends
  379.  
  380. udt_def    struc            ; upper dispatch table
  381.     dd    0        ; back pointer to cct
  382. reqadd    dd    0        ; request address
  383. xchain    dd    0        ; TransmitChain address
  384.     dd    0        ; TransferData address
  385.     dd    0        ; ReceiveRelease address
  386. indon    dd    0        ; IndicationOn address
  387. indoff    dd    0        ; IndicationOff address
  388. udt_def    ends
  389.  
  390. ldt_def    struc            ; lower dispatch table
  391.     dd    0        ; back pointer to cct
  392.     dd    2        ; interface flags (2 means something)
  393.     dd    0        ; RequestConfirm address
  394.         dd    0        ; TransmitConfirm address
  395.        dd    0        ; ReceiveLookahead indication address
  396.     dd    0        ; IndicationComplete address
  397.     dd    0        ; ReceiveChain indication address
  398.     dd    0        ; status indication address
  399. ldt_def    ends
  400.  
  401. snd_def    struc            ; transmit buffer descriptor
  402.     dw    0        ; byte count of immediate data (always 0)
  403.     dd    0        ; address of immediate data
  404.     dw    1        ; count of data blocks (always 1)
  405.     db    0        ; pointer type (0 == physical)
  406.     db    0        ; reserved
  407. snd_len    dw    0        ; number of bytes to send
  408. snd_off    dw    0        ; offset of data to send
  409. snd_seg    dw    0        ; segment of data to send
  410. snd_def    ends
  411.  
  412. rcv_def    struc        ; receive buffer descriptor
  413.     dw    1        ; count of data blocks (always 1)
  414.     db    0        ; pointer type (0 == physical)
  415.     db    0        ; reserved
  416. rcv_len    dw    0        ; number of bytes to get
  417. rcv_off    dw    0        ; offset of data to get
  418. rcv_seg    dw    0        ; segment of data to get
  419. rcv_def    ends
  420.  
  421. req_def    struc        ; Request block - Protocol Manager primitives
  422. req_opc    dw    0        ; opcode for PM request
  423. req_sta    dw    0        ; status returned from request
  424. req_of1    dw    0        ; first parameter pointer
  425. req_sg1    dw    0
  426. req_of2    dw    0        ; second parameter pointer
  427. req_sg2    dw    0
  428. req_prm    dw    0        ; parameter word
  429. req_def    ends
  430.  
  431. bnd_def    struc            ; binding list 
  432. bnd_cnt    dw    1        ; number of MACs to bind to -- 0 or 1
  433. bnd_nam    db    16 dup (0)    ; name of module to bind to
  434. bnd_def    ends
  435.  
  436.  
  437.     SUBTTL    Resident Data Area
  438.     PAGE
  439.  
  440. CSEG    SEGMENT PARA PUBLIC 'CODE'
  441.     assume    cs:CSEG, ds:CSEG, es:nothing
  442.  
  443. ; DEVICE HEADER - must be at offset zero within device driver
  444.     DD    -1        ; becomes pointer to next device header
  445.     DW    8000H        ; attribute (char device)
  446.     DW    OFFSET strat    ; pointer to device strategy routine
  447.     DW    OFFSET intr    ; pointer to device interrupt handler
  448.     DB    "PKTDRV$ "    ; device driver name
  449. ; END OF DEVICE HEADER
  450.  
  451. mac_cctp    dd    0    ; address of MAC's cct table
  452. mac_ds        dw    0    ; DS register for MAC
  453. rtn_cod        dw    0    ; Save NDIS return code here
  454.  
  455. drv_cct        cct_def    <>    ; Common Characteristics Table
  456. drv_ldt        ldt_def    <>    ; Lower Dispatch Table
  457. drv_snd        snd_def    <>    ; Argument blocks for NDIS TransmitChain,
  458. drv_rcv        rcv_def    <>    ;  TransferData,
  459. drv_bnd        bnd_def    <>    ;  and Bind (via DOS IOCTL)
  460. drv_req        req_def    <>    ; Argument block for general NDIS requests
  461. TransmitChain    dd    0        ; MAC entry point to send packet
  462. TransferData    dd    0        ; MAC entry point for data copy
  463. Request        dd    0        ; MAC entry point for requests
  464. ReceiveRelease    dd    0        ; MAC entry point (???not used???)
  465. IndicationOn    dd    0        ; MAC entries to control Indications
  466. IndicationOff    dd    0        ;  (upcalls) from NDIS
  467. req_con_flg    dw    REQUEST_QUEUED    ; Completion status from NDIS upcall
  468.  
  469. init_flg    db    0        ; Non-zero if we've been initialized
  470. address        db    16 dup (0)    ; Current address from MAC
  471. bytcnt        dw    0        ; Bytes copied by TransferData
  472. xmt_cmp        dw    SUCCESS        ; TransmitChain result
  473. open_adap    dw    0        ; OpenAdapter & SetPacketFilter result
  474.  
  475. ; Request Header (RH) address, saved here by "strategy" routine
  476.  
  477. req_hdr        LABEL    DWORD
  478. req_off        dw    0
  479. req_seg        dw    0
  480.  
  481. ; Save the request header for use by the interrupt routine
  482.  
  483. strat    PROC    FAR
  484.     mov    word ptr cs:req_off,bx    ; offset
  485.     mov    word ptr cs:req_seg,es    ; segment
  486.     ret
  487. strat    ENDP
  488.  
  489.     EVEN                    ; Get into word alignment
  490.  
  491. ;;
  492. ;; Data for Packet Driver
  493. ;;
  494. BAD_HANDLE    EQU 1    ; invalid handle number
  495. NO_CLASS    EQU 2    ; no interfaces of this class found
  496. NO_TYPE        EQU 3    ; no interfaces of specified type found
  497. NO_NUMBER    EQU 4    ; no interfaces of specified number found
  498. BAD_TYPE    EQU 5    ; bad packet type specified
  499. NO_MULTICAST    EQU 6    ; this interface does not support multicast
  500. CANT_TERMINATE    EQU 7    ; this packet driver cannot terminate
  501. BAD_MODE    EQU 8    ; an invalid receiver mode was specified
  502. NO_SPACE    EQU 9    ; operation failed because of insufficient space
  503. TYPE_INUSE    EQU 10    ; type had previously been accessed and not released
  504. BAD_COMMAND    EQU 11    ; the command was out of range or not implemented
  505. CANT_SEND    EQU 12    ; the packet couldn't be sent (usually hardware error)
  506. CANT_SET    EQU 13    ; The hardware address couldn't be changed
  507. BAD_ADDRESS    EQU 14    ; Hardware address has bad length or format
  508. CANT_RESET    EQU 15    ; Couldn't reset interface (more than 1 handle open)
  509.  
  510. PD_LEVEL    EQU    6    ; Implementation level (basic, high perf, ext)
  511. ANY_TYPE    EQU    0FFFFh    ; Matches any if_type
  512. ETHERADDR_LEN    EQU    6    ; Length of an Ethernet address
  513. ETHERTYPE_LEN    EQU    2    ; Length of Ethertypes
  514. ETHERTYPE_NONE    EQU    0    ; Ethertypes of 0 mean not defined
  515.  
  516. ; The connection arrays: types, and corresponding upcalls
  517.  
  518. PD_MAX_CONNS    EQU    20    ; The maximum number of handles/Types that can
  519.                 ;  be registered at one time
  520. MAX_P_LEN    equ    10    ; max length of TYPE matching field, bytes
  521.  
  522. per_handle    struc            ; Packet Driver HANDLE structure
  523. pd_conn_used    db    0        ; non-zero if this handle is in use
  524. pd_conn_type    db    MAX_P_LEN dup(0) ; associated packet type
  525. pd_conn_type_len dw    0        ; associated packet type length
  526. pd_conn_rmode    dw    3        ; receive mode for this handle
  527. pd_conn_rcvr    dd    0        ; receiver handler address
  528. pd_conn_class    db    0        ; interface class
  529. per_handle    ends
  530.  
  531. handles        per_handle PD_MAX_CONNS dup(<>)
  532. end_handles    label    byte
  533.  
  534. novell        db    0        ; if non-zero convert between old
  535.                     ; Novell 802.3 interior to Type 8137
  536.                     ; Caller used 8137, wire gets 802.3
  537.  
  538. ; Because some NDIS drivers can't support multiple calls to TransferData
  539. ; for a single reception, we only allow one handle (by implication, the last),
  540. ; to be in "match all" mode at a given time, but we do allow other handles
  541. ; to be open at the same time.
  542.  
  543. if_class    DB    1    ; Class 1 is Ethernet
  544. if_type        DW    57    ; NDIS to Packet Driver adapter
  545. pd_version    DW    9    ; Version
  546. conn_in_use    DW    0    ; Number of handles open
  547. pd_vector    DW    -1    ; Packet Driver vector to serve on
  548. pd_rcv_mode    DW    3    ; Default to rcv mode 3 (normal/bcast)
  549. pd_name        DB    "MAC/DIS converter", 0
  550. pd_recvall    db    0    ; non-zero if Promiscuous mode is active
  551. off        dw    12    ; offset to match bytes
  552. aoff        dw    0    ; offset to addresses
  553.  
  554. ; Table re-maps (badly) NDIS modes to Packet Driver modes (in parentheses)
  555. ndis_mode    db  0    ; No packets (0 == illegal)
  556.         db  0    ; No packets (1 == receiver off)
  557.         db  1    ; Directed | Multicast (2 should be directed only)
  558.         db  3    ; Directed | Multicast | Broadcast
  559.             ; (3 should be directed | broadcast)
  560.         db  3    ; Directed | limited Multicast | Broadcast
  561.             ; (4 == directed | broadcast | limited multicast)
  562.         db  3    ; Directed | limited Multicast | Broadcast
  563.             ; (5 should be directed | broadcast | all multicast)
  564.         db  4    ; Promiscuous (6 == match all)
  565.         
  566. EVEN    ; Get into word alignment
  567.  
  568. ; struct param; Pointer to this returned by get_parameters()
  569.  
  570. pd_param  db    1        ; Major revision = 1
  571.       db    9        ; Minor revision = 9
  572.       db    14        ; Length of this structure = 14
  573.       db    ETHERADDR_LEN    ; MAC addr length
  574. mtu      dw    1514        ; MAC packet length
  575.       dw    0        ; No multicast support
  576.       dw    0        ; No promises re: back-to-back receives
  577.       dw    0        ; No promises re: back-to-back transmits
  578. param_int dw    0        ; Default to no interrupt on EOI
  579.  
  580. ; Pointer to this returned by get_statistics
  581.  
  582. pd_statistics struc
  583. pkt_in        dd    0    ; Total packets in
  584. pkt_out        dd    0    ; Total packets out
  585. bytes_in    dd    0    ; Total bytes received
  586. bytes_out    dd    0    ; Total bytes sent
  587. errs_in        dd    0    ; Total transmit errors
  588. errs_out    dd    0    ; Total receive errors
  589. pkts_lost    dd    0    ; Packets dropped - no buffer, out of resc
  590. pd_statistics ends
  591.  
  592. pd_stat        pd_statistics <>    ; An instance of the above
  593.     
  594. PUBLIC    driver_info, access_type, release_type, send_pkt, terminate
  595. PUBLIC    get_address, reset_interface, get_parameters, set_rcv_mode
  596. PUBLIC    get_rcv_mode, get_statistics, set_address
  597.  
  598. ; Normal (basic Packet Driver functions) Jump Table
  599.  
  600. pd_table DW    pd_none        ; No handler
  601.     DW    driver_info    ; 1
  602.     DW    access_type    ; 2
  603.     DW    release_type    ; 3
  604.     DW    send_pkt    ; 4
  605.     DW    terminate    ; 5
  606.     DW    get_address    ; 6
  607.     DW    reset_interface    ; 7
  608. pd_table_size    EQU    ($-pd_table)/2
  609.  
  610. ; High Performance functions Jump Table
  611.  
  612. hp_table DW    get_parameters    ; 10
  613.     DW    pd_none        ; 11 (as_send_pkt not implemented)
  614. hp_table_size    EQU    ($-hp_table)/2
  615.  
  616. ; Extended functions Jump Table
  617.  
  618. ext_table DW    set_rcv_mode    ; 20
  619.     DW    get_rcv_mode    ; 21
  620.     DW    pd_none        ; 22 (set_multicast_list not implemented)
  621.     DW    pd_none        ; 23 (get_multicast_list not implemented)
  622.     DW    get_statistics    ; 24
  623.     DW    set_address    ; 25
  624. ext_table_size    EQU    ($-ext_table)/2
  625.  
  626. ;
  627. ; rcv_lah is the proc that handles ReceiveLookAhead upcalls from the MAC
  628. ;
  629. ; First, it determines if the packet is one that is wanted. If so, it asks
  630. ; the appropriate application for a buffer.  If it gets one, it copies the
  631. ; data and makes the 2nd call to the application to post it complete.  If
  632. ; not, it returns SUCCESS to the DIS driver anyway. It returns SUCCESS if
  633. ; if the packet was copied or FRAME_NOT_RECOGNIZED if it is not in the list
  634. ; of desired types.
  635. ;
  636. ;The stack coming into this call is:
  637. ;    dw    bp[20]        MACID
  638. ;    dw    bp[18]        framesize
  639. ;    dw    bp[16]        bytes available in buffer
  640. ;    dw    bp[14]        lookahead data address seg
  641. ;    dw    bp[12]        lookahead data address off
  642. ;    dd    bp[10]        indicate flag
  643. ;    dw    bp[6]        ds of called protocol mode (ME)
  644. ;
  645.  
  646. rcv_lah    PROC    FAR
  647.     push    bp
  648.     mov    bp,sp
  649.     push    bx            ; -2[bp]    ; save things
  650.     push    cx            ; -4[bp]
  651.     push    dx            ; -6[bp]
  652.     push    di            ; -8[bp]
  653.     push    ds            ; -10[bp]
  654.     push    es            ; -12[bp]
  655.     sub    sp,6            ; -14[bp]  handle
  656.                     ; -16[bp]  seg of PD buffer
  657.                     ; -18[bp]  offset of PD buffer
  658.     push    si
  659.     mov    ax,cs            ; setup data segment
  660.     mov    ds,ax
  661.  
  662.     mov    ax,14[bp]        ; segment of lookahead buffer
  663.     mov    es,ax
  664.     mov    di,12[bp]        ;  and its offset
  665.     call    pktfilter        ; apply packet filter
  666.     jnc    lah_get_buf        ; nc = we want this packet
  667.     mov    ax,FRAME_NOT_RECOGNIZED ; packet not accepted
  668.     jmp    lah_don
  669.  
  670. lah_get_buf:    ; Call Packet Driver receive routine to get its buffer address
  671.     mov    cx,18[bp]        ; CX = packet length
  672.     xor    ax,ax            ; AX = 0, 1st call to receiver
  673.     mov    -14[bp],bx        ; BX = handle, for next call
  674.     push    bp            ; we depend on BP
  675.     call    dword ptr cs:[bx].pd_conn_rcvr    ; Call the receive routine
  676.     pop    bp            ; Get BP back
  677.     mov    ax,es            ; Buffer address is in ES:DI
  678.     or    ax,ax            ; Check for segment of buffer,
  679.     jnz    rcvlha4            ; nz = ok
  680.     or    di,di            ; Check for offset of buffer,
  681.     jnz    rcvlha4            ; nz = ok
  682.     mov    ax,SUCCESS        ; No copy, accept pkt anyway
  683.     jmp    lah_don
  684.  
  685. rcvlha4:                ; Get data into buffer
  686.     mov    -16[bp],es
  687.     mov    -18[bp],di        ; save PD buffer pointer
  688.     mov    ax,offset bytcnt    ; Create far pointer to Addr
  689.     push    ds            ;  to put bytes copied into
  690.     push    ax            ;  and push it 
  691.     xor    ax,ax            ; Starting offset in frame
  692.     push    ax            ;  is always zero
  693. ;
  694. ; Set up recv table description
  695. ;
  696.     mov    ax,18[bp]        ; Len of recv data
  697.     mov    drv_rcv.rcv_len,ax    ;  goes in argument descriptor
  698.     mov    drv_rcv.rcv_seg,es    ;  as does far address of
  699.     mov    drv_rcv.rcv_off,di    ;  receive buffer
  700.     push    ds            ; Push far pointer to
  701.     mov    ax,offset drv_rcv    ;  descriptor
  702.     push    ax
  703.     mov    ax,mac_ds        ; Push MAC's DS value
  704.     push    ax
  705.     call    dword ptr cs:TransferData ; Copy pkt to buf (pops args)
  706. ;
  707. ; Call Packet Driver receive routine again (AX = 1) to finish up
  708. ;
  709.     mov    ax,-16[bp]        ; recover PD buffer pointer
  710.     mov    ds,ax
  711.     mov    si,-18[bp]        ; to DS:SI for second PD call
  712.     mov    cx,18[bp]        ; CX = packet length
  713.     mov    bx,-14[bp]        ; BX = handle
  714.     mov    ax,1            ; AX = 1 (second call)
  715.     call    dword ptr cs:[bx].pd_conn_rcvr    ; Call receive routine again
  716.     mov    ax,SUCCESS        ; we accepted the packet
  717. lah_don:pop    si
  718.     add    sp,6            ; local material
  719.     pop    es
  720.     pop    ds
  721.     pop    di
  722.     pop    dx
  723.     pop    cx
  724.     pop    bx
  725.     pop    bp
  726.     ret    16            ; Pop MAC's params off stack
  727. rcv_lah    ENDP
  728.  
  729. ;
  730. ; rcv_chn is the proc that handles ReceiveChain upcalls from the MAC
  731. ;
  732. ; First, it determines if the packet is one that is wanted. Then it tranfers
  733. ; the data into an internal buffer. it blocks any new indications until the 
  734. ; indicate complete upcall allows it the time to do a packet driver upcall.
  735. ; It returns success if the packet is ok or FRAME_NOT_RECOGNIZED if it is not 
  736. ; in the list of currently open types.
  737. ;
  738. ; The stack coming into this call is:
  739. ;    dw    bp[20]        MACID
  740. ;    dw    bp[18]        framesize
  741. ;    dw    bp[16]        request handle
  742. ;    dw    bp[14]        receive-chain buf descriptor address seg
  743. ;    dw    bp[12]        receive-chain buf descriptor address off
  744. ;    dd    bp[8]        indicate flag addr
  745. ;    dw    bp[6]        DS of called protocol mode (ME)
  746. ;
  747. ; where receive-chain buffer descriptor format is
  748. ;    dw    rxdatacount    count of received data blocks, max of 8
  749. ;    dw    rxdatalen    length of a data block
  750. ;    dd    rxdataptr    seg:offset of a data block
  751.  
  752. rcv_chn    PROC    FAR
  753.     push    bp
  754.     mov    bp,sp
  755.  
  756.     push    bx            ; -2[bp]    ; save things
  757.     push    cx            ; -4[bp]
  758.     push    dx            ; -6[bp]
  759.     push    di            ; -8[bp]
  760.     push    ds            ; -10[bp]
  761.     push    es            ; -12[bp]
  762.     sub    sp,2            ; -14[bp]  handle
  763.     push    si
  764.     mov    ax,cs            ; setup data segment (== CS)
  765.     mov    ds,ax
  766.     mov    ax,14[bp]        ; seg of rcv-chain buffer descriptor
  767.     mov    es,ax
  768.     mov    di,12[bp]        ;  and its offset
  769.     les    di,es:[di+4]        ; es:di is now the buffer pointer
  770.     call    pktfilter        ; apply packet filter, return handle
  771.     jnc    chn_get_buf        ; nc = we want this packet
  772.     mov    ax,FRAME_NOT_RECOGNIZED    ; packet not accepted
  773.     jmp    chn_don
  774.  
  775.     ;; Call the Packet Driver receive routine to get its buffer address
  776. chn_get_buf:
  777.     mov    cx,18[bp]        ; CX = packet length
  778.     xor    ax,ax            ; AX = 1st call to receiver
  779.          mov    -14[bp],bx        ; remember handle for next call
  780.     push    bp            ; We depend on BP
  781.     call    dword ptr cs:[bx].pd_conn_rcvr     ; Call the receive routine
  782.     pop    bp            ; Restore BP
  783.  
  784.     ; Now protocol stack's buffer address is in ES:DI
  785.     mov    ax,es
  786.     or    ax,ax            ; Check for non-zero segment
  787.     jne    rcvchn4            ; ne = ok
  788.     or    di,di            ; Check for non-zero offset
  789.     jne    rcvchn4            ; ne = ok
  790.     mov    ax,SUCCESS        ; No copy, accept pkt anyway
  791.     jmp    chn_don
  792.  
  793. rcvchn4:    ;; Get data from NDIS buffer(s) into protocol stack's buffer
  794.     push    ds            ; Save to restore after call 
  795.     push    es            ; Save ES:DI (pointer) to pass
  796.     push    di            ;  back to receiver later
  797.     lds    si,12[bp]        ; Addr of rcv descriptor
  798.     mov    cx,[si]            ; Get number of data blocks
  799.     add    si,2            ;  & move to top of list
  800.  
  801. chn_dat:        ; Move data from next block into stack's buffer
  802.     push    cx
  803.     push    ds
  804.     push    si
  805.     mov    cx,[si]            ; Get byte count of block
  806.     add    si,2
  807.     lds    si,[si]            ; Get far pointer to data
  808.     cld
  809.     shr    cx, 1
  810.     jnc    rcvchn5            ; nc = even already
  811.     movsb                ; Move 1 byte if count is odd
  812. rcvchn5:rep    movsw            ; Use word mov for efficiency
  813.     pop    si            ; Go through rest of chain
  814.     add    si,6
  815.     pop    ds
  816.     pop    cx
  817.     loop    chn_dat            ; For all blocks
  818. ;
  819. ; Call Packet Driver receive routine again to finish up
  820. ;
  821.     pop    si            ; DS:SI = buffer pointer
  822.     pop    ds            ;  that we're completing
  823.     mov    cx,18[bp]        ; CX = packet length
  824.     mov    bx,-14[bp]        ; BX = handle
  825.     mov    ax,1            ; Indicate 2nd (AX == 1) call
  826.     call    dword ptr cs:[bx].pd_conn_rcvr     ; Call receive routine again
  827.     mov    ax,SUCCESS        ; We accepted the packet
  828.     pop    ds            ; Now we're done with DS
  829.  
  830. chn_don:pop    si
  831.     add    sp,2
  832.     pop    es
  833.     pop    ds
  834.     pop    di
  835.     pop    dx
  836.     pop    cx
  837.     pop    bx
  838.     pop    bp
  839.     ret    16            ; pop params off stack
  840. rcv_chn    ENDP
  841.  
  842. ; Worker for lookahead and receive_chain procedures above. Checks PD handles
  843. ; for wanting this kind of packet. Returns carry clear and BX = handle
  844. ; if packet is wanted, else carry set to reject the packet. Expects MAC layer
  845. ; to provide at least our needed number of bytes (14+).
  846. ; Destroys AX, CX, DX, SI, preserves DI, ES, sets BX. Expects DS = CS.
  847. pktfilter proc    near
  848.     cmp    conn_in_use,0        ; any requests active?
  849.     jnz    pktfil1            ; e = no, exit no-match
  850.     jmp    pktfil11
  851. pktfil1:mov    dx,di            ; es:di is data pointer, save here
  852.     mov    bx,offset handles    ; BX = offset of handle table
  853.     mov    cx,PD_MAX_CONNS        ; CX = entries in table
  854. pktfil2:push    cx            ; save loop counter
  855.     cmp    [bx].pd_conn_used,0    ; is handle in use?
  856.     jne    pktfil4
  857.     jmp    pktfil9            ; e = no, do next handle
  858. pktfil4:lea    si,[bx].pd_conn_type    ; TYPE wanted by this handle
  859.     mov    cx,[bx].pd_conn_type_len; number of bytes to match
  860.     or    cx,cx
  861.     jnz    pktfil6            ; nz = do not match all packets
  862. pktfil5:jmp    pktfil12        ; match all packets
  863. pktfil6:mov    ax,[bx].pd_conn_rmode    ; receive mode
  864.     cmp    ax,6            ; Promiscuous?
  865.     je    pktfil5            ; e = yes, accept packet
  866.     mov    di,dx            ; es:di is lookahead data ptr
  867.     cmp    if_class,3        ; Token Ring 802.5 Class 3 interface?
  868.     jne    pktfil7            ; ne = no
  869.     test    byte ptr es:8[di],80h    ; routing info present? 
  870.     jz    pktfil7            ; z = no
  871.     push    cx
  872.     mov     cl,es:14[di]        ; get length of routing info
  873.     and    cx,1fh            ; just 5 bits worth
  874.     add    di,cx            ; skip over routing info
  875.     pop    cx
  876. pktfil7:add    di,off            ; skip to TYPE field et seq
  877.                     ; do old Novell 802.3 to Type 8137
  878.     cmp    if_class,1        ; regular Ethernet?
  879.     jne    pktfil8            ; ne = no
  880.     cmp    novell,0        ; doing old Novell conversion?
  881.     je    pktfil8            ; e = no
  882.     cmp    word ptr es:[di+2],0ffffh ; have the bad DSAP/SSAP signature?
  883.     jne    pktfil8            ; ne = no
  884.     mov    ax,es:[di]        ; get length/Type field value
  885.     xchg    ah,al            ; low endian form
  886.     cmp    ax,1500            ; size is larger than length?
  887.     jae    pktfil8            ; ae = yes, a protocol type
  888.     mov    word ptr es:[di],3781h    ; force in Novell Type 8137
  889.                     ; end of Novell section
  890. pktfil8:cld
  891.     repe    cmpsb            ; check for matching TYPE
  892.     je    pktfil12            ; e = match
  893.                     ; If Promiscuous mode do manual filter
  894.     cmp    pd_recvall,0        ; doing Promiscuous mode?
  895.     je    pktfil9            ; e = no, next handle
  896.     mov    si,offset address    ; our board's Ethernet addr
  897.     mov    cx,ETHERADDR_LEN    ; length of an Ethernet address
  898.     mov    di,dx            ; lookahead buffer
  899.     add    di,aoff
  900.     cld                ; look at destination address
  901.     repe    cmpsb            ; look for our Ethernet address
  902.     je    pktfil12            ; e = matched, accept lookahead
  903.     cmp    ax,2            ; ignore multicast and broadcast?
  904.     jbe    pktfil9            ; be = yes
  905.     mov    di,dx            ; recover offset of start of buffer
  906.     add    di,aoff
  907.     test    byte ptr es:[di],80h    ; multicast bit set?
  908.     jnz    pktfil12            ; nz = yes, accept lookahead
  909.     cmp    ax,3            ; accepting broadcasts?
  910.     jb    pktfil9            ; b = no
  911.     mov    al,0ffh            ; look for broadcast
  912.     mov    cx,ETHERADDR_LEN
  913.     repe    scasb            ; scan for all 0xFF's
  914.     je    pktfil12            ; e = matched, a broadcast
  915. pktfil9:add    bx,size per_handle    ; next entry
  916.     pop    cx            ; recover loop counter
  917.     dec    cx            ; mechanical loop
  918.     or    cx,cx            ; end of loop?
  919.     jz    pktfil10        ; z = yes
  920.     jmp    pktfil2            ; try next one
  921. pktfil10:mov    di,dx            ; restore di
  922. pktfil11:stc                ; carry set = no match found
  923.     ret
  924.  
  925. pktfil12:pop    cx            ; clean loop counter from stack
  926.     mov    di,dx            ; restore di
  927.     clc                ; carry clear = have match
  928.     ret
  929. pktfilter endp
  930.  
  931. ;
  932. ; Services indication complete upcall
  933. ;
  934. ; Executes interrupt (returned by get_parameters()) to pass control to
  935. ; an application which wants to run after the EOI.
  936. ;
  937. ; NOTE: Interrupt number at label ind_int is over-written if a different
  938. ;    interrupt is configured in protocols.ini.
  939. ;
  940. ind_com    PROC    FAR            ; Indication_complete upcall
  941.     push    es
  942.     push    bx
  943.         xor    ax,ax
  944.     mov    es,ax            ; Point ES at interrupt segment
  945.     mov    bx,cs:param_int        ; Get offset of vector
  946.     or    bx,bx            ; Is there one?
  947.     jz    ind_no_int        ; z = no, don't do the interrupt
  948.     shl    bx,1            ; Multiply by 4 for memory offset
  949.     shl    bx,1
  950.     cmp    word ptr es:[bx]+2,0    ; Is there a segment there?
  951.     jne    ind_int            ; ne = yes
  952.     cmp    word ptr es:[bx],0    ; Is there an offset there?
  953.     je    ind_no_int        ; no, no interrupt
  954. ind_int:                ; INT 65 overwritten if selected
  955.     INT    65h            ; Pass control to the application
  956.  
  957. ind_no_int:
  958.     pop    bx            ; Restore registers
  959.     pop    es
  960.     mov    ax,SUCCESS
  961.     ret    4
  962. ind_com    ENDP
  963.  
  964. ;;;;;;;;;;;;;;;;;;;;;;;;; Packet Driver section 
  965. regs    struc                ; stack offsets of incoming regs
  966.     _ES    dw    ?
  967.     _DS    dw    ?
  968.     _BP    dw    ?
  969.     _DI    dw    ?
  970.     _SI    dw    ?
  971.     _DX    dw    ?
  972.     _CX    dw    ?
  973.     _BX    dw    ?
  974.     _AX    dw    ?
  975.     _IP    dw    ?
  976.     _CS    dw    ?
  977.     _F    dw    ?        ; flags, Carry flag is bit 0
  978. regs    ends
  979. bytes    struc                ; stack offsets of incoming regs
  980.         dw    ?        ; es, ds, bp, di, si are 16 bits
  981.         dw    ?
  982.         dw    ?
  983.         dw    ?
  984.         dw    ?
  985.     _DL    db    ?
  986.     _DH    db    ?
  987.     _CL    db    ?
  988.     _CH    db    ?
  989.     _BL    db    ?
  990.     _BH    db    ?
  991.     _AL    db    ?
  992.     _AH    db    ?
  993. bytes    ends
  994.  
  995. CY    equ    0001h            ; to set caller's carry bit
  996.  
  997. ;
  998. ; Interrupt handler for the Packet Driver interface (protocol stack downcalls)
  999. ;
  1000. ; NOTE: Leaves interrupts disabled on entry - code in access_type and
  1001. ;    release_type depends on this.  send_pkt enables interrupts for MAC.
  1002. ;
  1003.     PUBLIC    pd_isr
  1004. pd_isr    PROC    FAR
  1005.     jmp    short over    ; skip the string (this MUST be a 3 byte jmp)
  1006.     nop            ; make three bytes
  1007.           DB    "PKT DRVR",0    ; string to identify a packet driver
  1008. over:
  1009.     push    ax
  1010.     push    bx
  1011.     push    cx
  1012.     push    dx
  1013.     push    si
  1014.     push    di
  1015.     push    bp
  1016.     push    ds
  1017.     push    es
  1018.     cld
  1019.     push    cs            ;set up ds to this code segment
  1020.     pop    ds
  1021.  
  1022.     mov    bp,sp            ;we use bp to access the original regs
  1023.     and    _F[bp],not CY        ;start by clearing the carry flag
  1024.     mov    _DH[bp],0        ; put no-error code in caller's DH
  1025.  
  1026.     cmp    ah,pd_table_size    ; AH too large?
  1027.     jae    highperf_table        ; ae = yes, try next set
  1028.                     ; Dispatch on AH using normal table
  1029.     mov    bl,ah            ; Get function code
  1030.     xor    bh,bh            ;  into a word register
  1031.     shl    bx,1            ; index by words
  1032.     jmp    pd_table[bx]        ; and go
  1033.  
  1034. highperf_table:
  1035.     sub    ah, 10        ; Offset of 1st high-performance function
  1036.     jl    pd_none            ; l = ah is out of range
  1037.     cmp    ah,hp_table_size    ; is AH still in range?
  1038.     jae    xtend_table        ; ae = no, try next set
  1039.                 ; Dispatch on AH using high-performance table
  1040.     mov    bl,ah            ; Get function code
  1041.     xor    bh,bh            ;  into a word register
  1042.     shl    bx,1            ; index by words
  1043.     jmp    hp_table[bx]        ; and go
  1044.  
  1045. xtend_table:
  1046.     sub    ah,10            ; Offset of 1st extended function
  1047.     jl    pd_none            ; l = AH is not in range
  1048.     cmp    ah,ext_table_size     ; still in range?
  1049.     jae    pd_none            ; ae = no
  1050.                     ; Dispatch on AH using extended table
  1051.     mov    bl,ah            ; Get function code
  1052.     xor    bh,bh            ;  into a word register
  1053.     shl    bx,1            ; index by words
  1054.     jmp    ext_table[bx]        ; and go
  1055.  
  1056. pd_none:
  1057.     mov    dh,BAD_COMMAND        ; set error code
  1058. err_ret:
  1059.     mov    _DH[bp],dh        ; put error code in caller's DH
  1060.     or    _F[bp],CY        ; set caller's carry flag
  1061. good_ret:                ; good return (carry clear)
  1062.     pop    es
  1063.     pop    ds
  1064.     pop    bp
  1065.     pop    di
  1066.     pop    si
  1067.     pop    dx
  1068.     pop    cx
  1069.     pop    bx
  1070.     pop    ax
  1071.     iret
  1072.  
  1073. ;
  1074. ; Checks the handle in BX.  If out of range or not valid cleans up the
  1075. ; stack and jumps directly to err_ret with a BAD_HANDLE error.  Assumes
  1076. ; called with DS pushed and a near call.  If handle is good, just returns.
  1077. ; BX is shifted one bit to the left.
  1078. ;
  1079.  
  1080. ; Bounds check on handle
  1081. chk_hdl    PROC     NEAR
  1082.     mov    bx,_BX[BP]        ; Handle
  1083.     cmp    bx,offset handles    ; start of handles area
  1084.     jb    chkhdl1            ; b = out of range
  1085.     cmp    bx,offset end_handles    ; end of handles area
  1086.     jae    chkhdl1            ; ae = above max table size
  1087.     cmp    [bx].pd_conn_used,0    ; is handle used?
  1088.     je    chkhdl1            ; e = no, go bomb out
  1089.     ret                ; return BX as handle
  1090. chkhdl1:
  1091.     pop    ds            ;clear stack (was the return address)
  1092.     mov    dh,BAD_HANDLE        ;return BAD_HANDLE error
  1093.     jmp    err_ret
  1094. chk_hdl    ENDP
  1095.  
  1096. ; The following implement the individual Packet Driver commands, basic
  1097. ; functions first.
  1098. ;
  1099. ; Send a packet.
  1100. ;
  1101. send_pkt:
  1102.     mov    xmt_cmp,REQUEST_QUEUED    ; set up for queued data
  1103.     mov    bx,_BX[bp]        ; handle
  1104.     mov    dx,_DS[bp]        ; get ds of data block to dx
  1105.     mov    cx,_CX[bp]
  1106.     mov    si,_SI[bp]
  1107.     mov    ax,drv_cct.mod_id    ; put our module id
  1108.     push    ax
  1109.     push    ds            ; request handle - good as any
  1110.             ; do conversion of Type 8137 to old Novell 802.3
  1111.     cmp    if_class,1        ; regular Ethernet?
  1112.     jne    send_pkt3        ; ne = no, no conversion
  1113.     cmp    novell,0        ; doing Novell packet conversion?
  1114.     je    send_pkt3        ; e = no
  1115.     push    es
  1116.     mov    es,dx            ; segment of packet
  1117.     cmp    word ptr es:[si+12],3781h ; outgoing Novell Type 8137?
  1118.     jne    send_pkt2        ; ne = no
  1119.     mov    ax,es:[si+12+4]        ; get internal length indicator
  1120.     xchg    ah,al
  1121.     inc    ax            ; round up to an even length
  1122.     and    al,not 1
  1123.     xchg    ah,al
  1124.     mov    es:[si+12],ax        ; change packet Type field to length
  1125. send_pkt2:pop    es            ; end of Novell conversion
  1126.  
  1127. send_pkt3:
  1128.     mov    drv_snd.snd_len,cx    ; save byte count in descriptor
  1129.     mov    drv_snd.snd_off,si    ; store offset of pkt buffer
  1130.     mov    drv_snd.snd_seg,dx    ; store segment of pkt buffer
  1131.     mov    bx,offset drv_snd    ; get addr of xmit buff desc
  1132.     push    ds            ; store on stack
  1133.     push    bx
  1134.     mov    ax,mac_ds        ; MACID
  1135.     push    ax
  1136.     sti                ; enable ints just to be sure
  1137.     call    TransmitChain        ; do downcall to NDIS
  1138.     xor    dx,dx            ; clear return code
  1139.     cmp    ax,SUCCESS        ; done?
  1140.     je    send_pkt4        ; e = yes, success
  1141.     cmp    ax,REQUEST_QUEUED    ; queued?
  1142.     jne    send_pkt5        ; ne = no
  1143. send_pkt4:jmp    good_ret        ; queued is ok
  1144.  
  1145. send_pkt5:
  1146.     mov    dh,CANT_SEND        ; trouble, fail
  1147.     jmp    err_ret
  1148.  
  1149.  
  1150. ;
  1151. ; Handle driver_info() downcall - return driver information.
  1152. ;
  1153. driver_info:
  1154.     mov    bx,pd_version        ; BX is version
  1155.     mov    ch,if_class        ; CH is class
  1156.     mov    dx,if_type        ; DX is type
  1157.     xor    cl,cl            ; CL is interface number (always 0)
  1158.     mov    _BX[bp],bx
  1159.     mov    _CX[bp],cx
  1160.     mov    _DX[bp],dx
  1161.     mov    _SI[bp],offset pd_name    ; ds:si is ptr to name
  1162.     mov    ax,ds
  1163.     mov    _DS[bp],ax
  1164.     mov    al,PD_LEVEL        ; Level of implementation
  1165.     xor    ah,ah
  1166.     mov    _AX[bp],ax
  1167.     jmp    good_ret
  1168.  
  1169. ;
  1170. ; Handle access_type() - sets up to handle an Ethernet packet type.
  1171. ;
  1172. ; NOTE:    Depends on entry with interrupts disabled for shared data locking.
  1173. ;
  1174. access_type_class:
  1175.     mov    dh,NO_CLASS
  1176.     jmp    err_ret
  1177.  
  1178. access_type_type:
  1179.     mov    dh,NO_TYPE
  1180.     jmp    err_ret
  1181.  
  1182. access_type_number:
  1183.     mov    dh,NO_NUMBER
  1184.     jmp    err_ret
  1185.  
  1186. access_type_bad:
  1187.     mov    dh,BAD_TYPE
  1188.     jmp    err_ret
  1189.  
  1190. access_type:
  1191.     mov    al,if_class
  1192.     cmp    _AL[bp],al        ; our class?
  1193.     jne    access_type_class    ; ne = no, fail
  1194. access_type_1:
  1195. ;    cmp    _BX[bp],ANY_TYPE    ; generic type?
  1196. ;    je    access_type_2        ; e = yes
  1197. ;    mov    al,driver_type
  1198. ;    cbw
  1199. ;    cmp    _BX[bp],ax        ; our type?
  1200. ;    jne    access_type_type    ; ne = no
  1201. access_type_2:
  1202.     cmp    _DL[bp],0        ; generic number?
  1203.     je    access_type_3        ; e = yes
  1204.     cmp    _DL[bp],1        ; our number?
  1205.     jne    access_type_number    ; ne = no
  1206. access_type_3:
  1207.     cmp    _CX[bp],MAX_P_LEN    ; is the type length too long?
  1208.     ja    access_type_bad        ; a = yes, this can't be ours
  1209.  
  1210. ; now we do two things--look for an open handle, and check the existing
  1211. ; handles to see if they're replicating a packet type.
  1212.  
  1213.     xor    dx,dx            ; remember no free handle yet
  1214.     mov    bx,offset handles    ; first handle
  1215.     cld
  1216. access_type_4:
  1217.     cmp    [bx].pd_conn_used,0    ; is this handle in use?
  1218.     je    access_type_5        ; e = no, do not check the type
  1219.     mov    al,_AL[bp]        ; is this handle the same class as
  1220.     cmp    al,[bx].pd_conn_class    ;  they want?
  1221.     jne    short access_type_6    ; ne = no
  1222.     mov    es,_DS[bp]        ; get a pointer to their type
  1223.     mov    di,_SI[bp]        ;  from their ds:si to our es:di
  1224.     mov    cx,_CX[bp]        ; get the minimum of their length
  1225.                     ;  and our length.  As currently
  1226.                     ;  implemented, only one receiver
  1227.                     ;  gets the packets, so we have to
  1228.                     ;  ensure that the shortest prefix
  1229.                     ;  is unique.
  1230.     mov    si,[bx].pd_conn_type_len ; length of their Type
  1231.     cmp    cx,si            ; are we less specific than they are?
  1232.     jb    access_type_8        ; b = no
  1233.     mov    cx,si            ; yes, use their (shorter) length
  1234. access_type_8:
  1235.     lea    si,[bx].pd_conn_type    ; their desired Type
  1236.     or    cx,cx            ; pass-all TYPE? (zero TYPE length)
  1237.     jnz    access_type_7        ; nz = no
  1238.     mov    bx,offset handles+(PD_MAX_CONNS-1)*(size per_handle)
  1239.  
  1240.     jmp    short access_type_5    ; put pass-all last
  1241. access_type_7:
  1242.     repe    cmpsb            ; same type? (conflict if so)
  1243.     jne    short access_type_6    ; ne = no, go look at the next one
  1244. access_type_inuse:
  1245.     mov    dh,TYPE_INUSE        ; a handle has been assigned for TYPE
  1246.     jmp    err_ret            ; cannot assign a type
  1247.  
  1248. access_type_5:                ; handle is not in use
  1249.     or    dx,dx            ; found a free handle yet?
  1250.     jne    access_type_6        ; ne = yes
  1251.     mov    dx,bx            ; remember first free handle in dx
  1252. access_type_6:
  1253.     add    bx,(size per_handle)    ; go to the next handle
  1254.     cmp    bx,offset end_handles    ; examined all handles?
  1255.     jb    access_type_4        ; b = no, continue
  1256.     mov    bx,dx            ; did we find a free handle?
  1257.     or    bx,bx
  1258.     jz    access_type_space    ; z = no, return error
  1259.  
  1260.     mov    [bx].pd_conn_used,1    ; remember that we're using it
  1261.     mov    ax,_DI[bp]        ; get receiver address from ES:DI
  1262.     mov    word ptr [bx].pd_conn_rcvr,ax    ; offset part
  1263.     mov    ax,_ES[bp]
  1264.     mov    word ptr [bx].pd_conn_rcvr+2,ax    ; segment part
  1265.  
  1266.     push    ds
  1267.     mov    ax,ds
  1268.     mov    es,ax
  1269.     mov    ds,_DS[bp]        ; remember their type
  1270.     mov    si,_SI[bp]
  1271.     mov    cx,_CX[bp]
  1272.     mov    es:[bx].pd_conn_type_len,cx    ; remember the TYPE length
  1273.     lea    di,[bx].pd_conn_type
  1274.     rep    movsb            ; copy TYPE field to match
  1275.     pop    ds
  1276.     inc    conn_in_use        ; count handles in use
  1277.     mov    al,_AL[bp]        ; remember Class
  1278.     mov    [bx].pd_conn_class,al
  1279.     mov    _AX[bp],bx        ; return handle in caller's AX
  1280.     call    chk_rmode        ; update Promiscous mode status
  1281.     jmp    good_ret
  1282.  
  1283. access_type_space:
  1284.     mov    dh,NO_SPACE
  1285.     jmp    err_ret
  1286. ;
  1287. ; Perform release_type() - forget the packet type/upcall/handle
  1288. ;
  1289. ; NOTE:    Depends on entry with interrupts disabled for shared data locking.
  1290. ;
  1291. release_type:
  1292.     call    chk_hdl            ; get handle, return here if ok
  1293.                     ; This is a critical region!!
  1294.     mov    [bx].pd_conn_type,ETHERTYPE_NONE ; Clear connection
  1295.     mov    [bx].pd_conn_used,0    ; free handle-used indicator
  1296.     dec    conn_in_use        ; Count one less handle open
  1297.     call    chk_rmode        ; update Promiscous mode status
  1298.     jmp    good_ret
  1299. ;
  1300. ; Perform terminate() - never actually do it.
  1301. ;
  1302. terminate:
  1303.     call    chk_hdl            ; check handle
  1304.     mov    dh,CANT_TERMINATE    ; Return error
  1305.     jmp    err_ret
  1306.  
  1307. ;
  1308. ; Perform get_address() - get the current Ethernet address of the interface
  1309. ;
  1310. get_address:
  1311.     mov    ax,_AX[bp]
  1312.     mov    bx,_BX[bp]
  1313.     mov    cx,_CX[bp]
  1314.     mov    si,_SI[bp]
  1315.     mov    di,_DI[bp]
  1316.     mov    es,_ES[bp]
  1317.     cld
  1318.     cmp    cx,ETHERADDR_LEN    ; Make sure it's an ethernet address
  1319.     jne    get_address_err        ; ne = bad length, fail
  1320.     call    get_eaddr        ; address to caller's area
  1321.     mov    ax,ds
  1322.     mov    es,ax
  1323.     mov    di,offset address    ; where to store Ethernet address
  1324.     call    get_eaddr        ; get board's Ethernet address
  1325.     jmp    good_ret
  1326.  
  1327. get_address_err:
  1328.     mov    dh,NO_SPACE        ; hmmm, I suppose it's close enough
  1329.     jmp    err_ret
  1330.  
  1331. ; Return board's current Ethernet address in es:di (ETHERADDR_LEN bytes)
  1332. ; via NDIS information.
  1333. get_eaddr proc    near
  1334.     push    ds
  1335.     push    si
  1336.     push    cx
  1337.     push    es            ; preserve destination
  1338.     push    di
  1339.     les    si,mac_cctp        ; get address of mac cct
  1340.     lds    si,es:sscp[si]        ; get address of mac ssc
  1341.     add    si,cur_add        ; mov to offset in structure
  1342.     pop    di
  1343.     pop    es
  1344.     mov    cx,ETHERADDR_LEN    ; get length
  1345.     cld
  1346.     rep     movsb            ; copy address
  1347.     pop    cx
  1348.     pop    si
  1349.     pop    ds
  1350.     ret
  1351. get_eaddr endp
  1352.  
  1353. ;
  1354. ; Perform reset_interface() - this is ignored.
  1355. ;
  1356. reset_interface:
  1357.     call    chk_hdl            ; check handle
  1358.     jmp    good_ret        ; if the handle was good, call is good
  1359.  
  1360. ;
  1361. ; The following implement the High Performance functions
  1362. ;
  1363. ; get_parameters() - Return pointer to parameters structure in ES:DI
  1364. ;
  1365. get_parameters:
  1366.     mov    ax,cs
  1367.     mov    _ES[bp],ax        ; return struct adr in caller's ES:DI
  1368.     mov    _DI[bp],offset pd_param
  1369.     jmp    good_ret        ;  & pass it to caller
  1370.  
  1371. ;
  1372. ; as_send_pkt() - Not implemented.
  1373. ;
  1374. ;as_send_pkt:
  1375. ;    mov    dh,BAD_COMMAND
  1376. ;    jmp    err_ret
  1377.  
  1378. ;
  1379. ; The following implement the Extended functions
  1380. ;
  1381. ; set_rcv_mode translates the PDS mode to an NDIS Packet Filter.
  1382. ;
  1383. set_rcv_mode:
  1384.     call    chk_hdl            ; get handle, return here if ok
  1385.     mov    ax,_AX[bp]
  1386.     mov    cx,_CX[bp]
  1387.     jcxz    set_rcv_mode_err    ; z = illegal receive mode, quit
  1388.     cmp    cx,6            ; is mode legal?
  1389.     ja    set_rcv_mode_err    ; a = no, quit
  1390.     mov    bx,cx            ; Put it in an index register
  1391.     mov    bl,ndis_mode[bx]    ; and translate it for NDIS
  1392.     xor    bh,bh
  1393.     cmp    bl,4            ; NDIS Promiscuous mode?
  1394.     jb    set_rec_mode2        ; b = no
  1395.     push    es
  1396.     push    di
  1397.     les    di,mac_cctp        ; check if Promiscuous mode supported
  1398.     les    di,es:[di].sscp
  1399.     test    es:[di].svc_1,8        ; first 15 service flags, Promis bit
  1400.     jnz    set_rec_mode1        ; nz = mode is supported
  1401.     dec    bl            ; use regular NDIS mode 3 instead
  1402. set_rec_mode1:
  1403.     pop    di
  1404.     pop    es
  1405. set_rec_mode2:
  1406.     call    set_ndis_mode        ; Try to set it
  1407.     cmp    ax,SUCCESS        ; did it succeed?
  1408.     je    set_rcv_mode_ok        ; e = yes, return success
  1409. set_rcv_mode_err:
  1410.     mov    dh,BAD_MODE        ; no, return error
  1411.     jmp    err_ret
  1412.  
  1413. set_rcv_mode_ok:
  1414.     mov    bx,_BX[bp]        ; get handle again
  1415.     mov    cs:[bx].pd_conn_rmode,cx ; set receive mode in handle's struct
  1416.     mov    cs:pd_rcv_mode,cx    ; save the mode we just set
  1417.     call    chk_rmode        ; check on Promiscous mode
  1418.     jmp    good_ret        ;  and return ok
  1419.  
  1420.  
  1421. ; Examine all PD handles and set global variable pd_recvall to 0 if no handle
  1422. ; is doing Promiscuous mode receives, else non-zero.
  1423. chk_rmode proc    near
  1424.     push    bx
  1425.     push    cx
  1426.     push    ds
  1427.     mov    cx,cs
  1428.     mov    ds,cx
  1429.     mov    bx,offset handles    ; BX = offset of handle table
  1430.     mov    cx,PD_MAX_CONNS        ; CX = entries in table
  1431.     mov    pd_recvall,0        ; assume no Promiscous mode active
  1432. chk_rmode1:
  1433.     cmp    [bx].pd_conn_used,0    ; is handle in use?
  1434.     je    chk_rmode2        ; e = no, do next handle
  1435.     cmp    [bx].pd_conn_rmode,6    ; Promiscuous mode active here?
  1436.     jne    chk_rmode2        ; ne = no
  1437.     mov    pd_recvall,1        ; say Promiscous mode is active
  1438.     jmp    short chk_rmode3
  1439. chk_rmode2:
  1440.     loop    chk_rmode1
  1441. chk_rmode3:
  1442.     pop    ds
  1443.     pop    cx
  1444.     pop    bx
  1445.     ret
  1446. chk_rmode endp
  1447.  
  1448. ;
  1449. ; Return the current Packet Driver receive mode.
  1450. ;
  1451. get_rcv_mode:
  1452.     call    chk_hdl            ; get handle, return here if ok
  1453.     mov    ax,[bx].pd_conn_rmode    ; get mode for this handle
  1454.     mov    _AX[bp],ax
  1455.     jmp    good_ret        ; return it
  1456.  
  1457.  
  1458. get_statistics:
  1459.     les    si,mac_cctp        ; ES:SI == address of NDIS cct
  1460.     les    si,es:sssp[si]        ; ES:SI == address of NDIS sss
  1461.     mov    ax,es
  1462.     or    ax,ax            ; Is the segment non-zero?
  1463.     jnz    getsta1            ; nz = yes, accept it
  1464.     or    si,si            ; how about offset?
  1465.     jnz    getsta1            ; nz = ok
  1466.     mov    DH,BAD_COMMAND        ; If they don't implement it,
  1467.     jmp    err_ret            ;  neither do we
  1468.     
  1469. getsta1:mov    ax,cs
  1470.     mov    ds,ax
  1471.     mov    di,offset pd_stat        ; Get start of PD stats table
  1472.     cli                    ; Don't allow updates just now
  1473.     mov    ax,WORD PTR es:r_tot[si]    ; Copy total received frames
  1474.     mov    dx,WORD PTR es:r_tot+2[si]
  1475.     call    valchk
  1476.     mov    ax, WORD PTR es:x_tot[si]    ; Copy total xmitted frames
  1477.     mov    dx, WORD PTR es:x_tot+2[si]
  1478.     call    valchk
  1479.     mov    ax, WORD PTR es:rb_tot[si]    ; Copy total received bytes
  1480.     mov    dx, WORD PTR es:rb_tot+2[si]
  1481.     call    valchk
  1482.     mov    ax, WORD PTR es:xb_tot[si]    ; Copy total transmitted bytes
  1483.     mov    dx, WORD PTR es:xb_tot+2[si]
  1484.     call    valchk
  1485.     mov    ax, WORD PTR es:r_err[si]    ; Copy total receive errors
  1486.     mov    dx, WORD PTR es:r_err+2[si]
  1487.     call    valchk
  1488.     mov    ax, WORD PTR es:x_hwer[si]    ; Copy total transmit errors
  1489.     mov    dx, WORD PTR es:x_hwer+2[si]
  1490.     call    valchk
  1491.     mov    ax, WORD PTR es:r_drop[si]    ; Copy total receives dropped
  1492.     mov    dx, WORD PTR es:r_drop+2[si]
  1493.     call    valchk
  1494.     sti                    ; All done with shared data
  1495.     mov    _SI[bp],OFFSET pd_stat      ; set caller's DS:SI to the
  1496.     mov    ax,cs            ; address of Packet Driver stats
  1497.     mov    _DS[bp],ax
  1498.     jmp    good_ret
  1499.  
  1500. ; Convert double word dx:ax from NDIS unknown value of (long) -1 to (long) 0,
  1501. ; store results in ds:[di, di+2], move di forward two words.
  1502. valchk    proc    near
  1503.     cmp    ax,-1            ; starting at -1 (NDIS, for unknown)?
  1504.     jne    valchkx            ; ne = no
  1505.     cmp    dx,-1            ; this part too
  1506.     jne    valchkx            ; ne = no
  1507.     xor    ax,ax            ; zero counters for zero based counts
  1508.     xor    dx,dx
  1509. valchkx:mov    [di],ax            ; store results locally
  1510.     mov    [di+2],dx
  1511.     add    di,4            ; step to next storage double word
  1512.     ret
  1513. valchk    endp
  1514. ;
  1515. ; Perform set_address() - change physical address of the interface.
  1516. ;
  1517. ; The problem with this is that some NDIS drivers may just accept the
  1518. ; SetStationAddress call, but others may require a CloseAdapter/OpenAdapter
  1519. ; to bracket it.  This latter doesn't seem worth the effort at the moment.
  1520. ;
  1521. set_address:
  1522. IFDEF    DO_SET_ADDRESS
  1523.     
  1524.     mov    bx,_BX[bp]        ; Get handle (not checked)
  1525.     mov    cx,_CX[bp]
  1526.     cmp    cx,ETHERADDR_LEN    ; Make sure it's an ethernet address
  1527.     jne    set_address_err        ; Jump if bad length
  1528.  
  1529.     cmp    conn_in_use,1        ; How many handles are open?
  1530.     jbe    set_allowed        ; be = 1 or none, ok
  1531. set_err:
  1532.     mov    dh,CANT_SET        ; Too many - don't allow it
  1533.     jmp    err_ret
  1534.  
  1535. set_allowed:
  1536.     mov    ax, cs:drv_cct.mod_id    ; Make set station address call
  1537.     push    ax            ; Module ID of protocol
  1538.     inc    ax
  1539.     push    ax            ; Push request ID (0 to not conf)
  1540.     xor    bx,bx
  1541.     push    bx            ; Must be 0
  1542.     push    es            ; Push pointer to address to set
  1543.     push    di
  1544.     push    SET_STA_ADDR        ; SetStationAddress function code
  1545.     les    bx,mac_cctp
  1546.     mov    ax,es:[bx].mod_ds
  1547.     push    ax
  1548.     mov    cs:req_con_flg,REQUEST_QUEUED
  1549.     call    cs:Request        ; Make call to NDIS
  1550.     mov    cs:req_con_flg,ax
  1551.     sti                ; Wait for request to complete
  1552. setall1:
  1553.     cmp    ax,SUCCESS        ; success?
  1554.     je    setall2            ; e = yes
  1555.     cmp    ax,REQUEST_QUEUED    ; Is it queued?
  1556.     jne    set_err            ; ne = no, quit with CANT_SET
  1557.     mov    ax,cs:req_con_flg    ; get current status
  1558.     jmp    short setall1        ; keep polling
  1559. setall2:jmp    good_ret
  1560.  
  1561. set_address_err:
  1562.     mov    dh, BAD_ADDRESS        ; We didn't like the address
  1563.     jmp    err_ret
  1564. ELSE
  1565.     mov    dh, CANT_SET        ; Built this way, we can't set address
  1566.     jmp    err_ret
  1567. ENDIF
  1568.  
  1569. pd_isr    ENDP
  1570. ;;;;;; end of Packet Driver direct support procedures
  1571.  
  1572. ;
  1573. ; The following are upcalls from DIS:
  1574.  
  1575. ; RequestConfirm enters with stack of (after our push bp)
  1576. ;    dw    [BP+16]        ProtID
  1577. ;    dw    [BP+14]        MACID
  1578. ;    dw    [BP+12]        ReqHandle
  1579. ;    dw    [BP+10]        Status
  1580. ;    dw    [BP+8]        Request
  1581. ;    dw    [BP+6]        ProtDS (our DS)
  1582.  
  1583. req_con    PROC    FAR            ; Request Confirm 
  1584.     push    bp
  1585.     mov    bp,sp
  1586.     mov    ax,[bp+10]        ; get NDIS status response
  1587.     mov    cs:req_con_flg,ax    ; store in local area
  1588.     mov    ax,SUCCESS        ; return our feelings on the matter
  1589.     pop    bp
  1590.     ret    12
  1591. req_con    ENDP
  1592.  
  1593.  
  1594. ; TransmitConfirm enters with stack of (after our push bp)
  1595. ;    dw    [BP+14]        ProtID        
  1596. ;    dw    [BP+12]        MACID        
  1597. ;    dw    [BP+10]        ReqHandle
  1598. ;    dw    [BP+8]        Status        
  1599. ;    dw    [BP+6]        ProtDS (our DS)
  1600.         
  1601. xmt_con    PROC    FAR            ; Transmit Confirm
  1602.     push    bp
  1603.     mov    bp,sp
  1604.     mov    ax,8[bp]
  1605.     mov    cs:xmt_cmp,ax        ; moves the return code into static
  1606.     mov    ax,SUCCESS
  1607.     pop    bp
  1608.     ret    10
  1609. xmt_con    ENDP
  1610.  
  1611.  
  1612. sta_ind    PROC    FAR            ; Status handled, not used
  1613.     mov    ax,SUCCESS
  1614.     ret    12
  1615. sta_ind    ENDP
  1616.  
  1617.  
  1618. dis_pat    PROC    FAR            ; System entry point for pkt driver
  1619.     push    bp            ; Used only by initiate bind request
  1620.     mov    bp,sp
  1621.     mov    ax,8[bp]        ; Check opcode
  1622.     cmp    ax,1            ; Is it initiate_bind?
  1623.     je    dispat1            ; e = yes            
  1624.     mov    ax,GENERAL_FAILURE    ; NO: fail
  1625.     pop    bp
  1626.     ret    14
  1627.  
  1628. dispat1:push    ds            ; save stuff
  1629.     push    es
  1630.     push    bx
  1631.     push    cx
  1632.     push    si
  1633.     push    di
  1634.  
  1635.     mov    ax,cs            ; set up DS == CS
  1636.     mov    ds,ax            
  1637.     mov    bx,offset mac_cctp    ; Save addr of MAC's cct
  1638.     mov    ax,12[bp]
  1639.     mov    [bx],ax
  1640.     mov    ax,14[bp]
  1641.     mov    2[bx], ax
  1642.  
  1643.     mov    ax,offset drv_cct    ; push pkt drv cct (our cct)
  1644.     push    ds            
  1645.     push    ax
  1646.     mov    ax,offset mac_cctp    ; push addr for MAC's cct
  1647.     push    ds
  1648.     push    ax
  1649.     xor    ax,ax            ; pad parameter
  1650.     push    ax
  1651.     mov    ax,2            ; Load Bind command code
  1652.     push    ax
  1653.     les    bx,mac_cctp        ; load address of MAC's cct
  1654.     mov    ax,es:[bx].mod_ds
  1655.     push    ax            ; push MAC's ds
  1656.     call    dword ptr es:[bx].system ; call MAC's system entry point
  1657.     mov    rtn_cod,ax        ; remember return status
  1658.     or    ax,ax
  1659.     jz    dispat2            ; z = Bind succeeded
  1660.     MSG    bad_bind        ; tell the user the bad news
  1661.     jmp    rtn_dis            ; Bind failed, fatal error
  1662.  
  1663. dispat2:
  1664.     call    sav_mac            ; Save MAC entry point addresses
  1665.     les    bx,mac_cctp        ; Check if OpenAdapter needed
  1666.     les    bx,es:[bx].sscp
  1667.  
  1668.     lea    di,[bx].mtype        ; MAC type, asciiz
  1669.     mov    si,offset t8023        ; try 802.3
  1670.     mov    cx,t8023len
  1671.     cld
  1672.     repe    cmpsb
  1673.     je    is8023            ; e = matched
  1674.     lea    di,[bx].mtype
  1675.     mov    si,offset t8025        ; try 802.5 (Token Ring)
  1676.     mov    cx,t8025len
  1677.     repe    cmpsb
  1678.     je    is8025            ; e = matched
  1679.     jmp    short gottype
  1680. is8023:    mov    if_class,11        ; 802.3 with 802.2 (SNAP) headers
  1681.     mov    off,14            ; 6 MAC + 6 MAC + 2 LEN
  1682.     jmp    short gottype
  1683. is8025:    mov    if_class,3        ; Token Ring 802.5
  1684.     mov    off,14
  1685.     mov    aoff,2
  1686.     mov    ax,es:[bx].maxfram
  1687.     mov    mtu,ax
  1688. ;    jmp    short gottype
  1689.  
  1690. gottype:mov    ax,es:[bx].svc_1
  1691.     test    ax,0800h         ; OpenAdapter supported?
  1692.     jnz    dispat3            ; nz = yes, go do it
  1693.     jmp    open_ok1        ; skip to setting packet filter
  1694.  
  1695. dispat3:                ; Make OpenAdapter call to NDIS
  1696.     mov    ax,cs
  1697.     push    ax            ; module ID of protocol
  1698.     push    ax            ; unique handle (0 to not conf)
  1699. ifdef    ALLFRAMES
  1700.     mov    ax, 6
  1701.     push    ax
  1702. endif
  1703.     xor    ax,ax
  1704. ifndef    ALLFRAMES
  1705.     push    ax            ; dw pad
  1706. endif
  1707.     push    ax            ; dd pad
  1708.     push    ax
  1709.     mov    ax,OPEN_ADAPTER        ; OpenAdapter command code
  1710.     push    ax
  1711.     les    bx,mac_cctp
  1712.     mov    ax,es:[bx].mod_ds
  1713.     push    ax
  1714.     mov    cs:req_con_flg,REQUEST_QUEUED
  1715.     call    cs:Request        ; Make call to NDIS via indirect ptr
  1716.     mov    cs:req_con_flg,ax    ; Save immediate return code
  1717.  
  1718. dispat4:sti                ; Needed because of bugs in some MACs
  1719.     cmp    ax,SUCCESS
  1720.     jz    open_ok1
  1721.     cmp    ax,NOT_SUPPORTED
  1722.     jz    open_ok1
  1723.     cmp    ax,REQUEST_QUEUED    ; Was it queued?
  1724.     jne    dispat5            ; NO: bomb
  1725.     mov    ax,cs:req_con_flg
  1726.     jmp    short dispat4        ; keep polling
  1727.  
  1728. dispat5:MSG    bad_open_adpt        ; Fatal error: open adapter failed
  1729.     jmp    rtn_dis
  1730.  
  1731. open_ok1:
  1732.     mov    ax,cs            ; Temp fix for Apricot (may not
  1733.     mov    ds,ax            ;  be needed anymore)
  1734.     mov    ax,mac_ds
  1735.     push    ax
  1736.     call    IndicationOff
  1737.     mov    ax,mac_ds
  1738.     push    ax
  1739.     call    IndicationOn
  1740.     sti                ; Who disabled?  MAC bug probably
  1741.  
  1742.     mov    bx,3            ; Set default filter: Directed,
  1743.     call    set_ndis_mode        ;  Multicast & Broadcast (3)
  1744.     cmp    ax,SUCCESS        ; Did it work?
  1745.     je    set_vec            ; e = yes, go on to vector
  1746.     MSG    bad_set_pkt        ; show an error and fail
  1747.     jmp    rtn_dis
  1748.  
  1749. ; Give warning if the Packet Driver vector is already in use but use anyway
  1750.  
  1751. set_vec:
  1752.     xor    ax,ax            ; Set ES to 0 to look in int tab
  1753.     mov    es,ax
  1754.     mov    bx,cs:pd_vector        ; Get vector and multiply by 4
  1755.     shl    bx,1
  1756.     shl    bx,1
  1757.     mov    ax,es:[bx]
  1758.     or    ax,ax            ; Is segment zero?
  1759.     jnz    vin_use2        ; nz = yes, print warning
  1760.     mov    ax,es:2[bx]
  1761.     or    ax,ax            ; Is offset zero?
  1762.     jz    dispat6            ; z = no, don't print warning
  1763.  
  1764. vin_use2:
  1765.     MSG    vec_in_use        ; Print a warning
  1766. dispat6:
  1767.     mov    ax,offset pd_isr    ; move packet driver isr addr into
  1768.     mov    es:[bx],ax        ; interrupt vector table
  1769.     mov    ax,cs
  1770.     mov    es:2[bx],ax
  1771.     xor    ax,ax
  1772. rtn_dis:
  1773.     pop    di            ; all done
  1774.     pop    si
  1775.     pop    cx
  1776.     pop    bx
  1777.     pop    es
  1778.     pop    ds
  1779.     pop    bp
  1780.     ret    14
  1781. dis_pat    ENDP
  1782.  
  1783. ; Make the NDIS SetPktFilter call (both at bind and from set_rcv_mode)
  1784. ;
  1785. ; Arguments:
  1786. ;    BX    NDIS Packet filter to set (see DIS p 45 for bits)
  1787. ;         * 0 - directed and multicast
  1788. ;         * 1 - broadcast
  1789. ;           2 - promiscuous
  1790. ;           3 - any source routing packet
  1791. ;
  1792. set_ndis_mode PROC NEAR
  1793.     push    es            ; Save ES & BX registers
  1794.     push    bx
  1795.     mov    ax,cs:drv_cct.mod_id    ; make set packet filter call
  1796.     push    ax            ; module ID of protocol
  1797.     inc    ax
  1798.     push    ax            ; unique handle (0 to not conf)
  1799.     push    bx            ; Push packet filter value
  1800.     xor    ax,ax
  1801.     push    ax            ; dd pad
  1802.     push    ax
  1803.     mov    ax,SET_PKT_FLT        ; SetPacketFilter command
  1804.     push    ax
  1805.     les    bx,mac_cctp
  1806.     mov    ax,es:[bx].mod_ds
  1807.     push    ax
  1808.     mov    cs:req_con_flg,REQUEST_QUEUED
  1809.     call    cs:Request        ; Make call to NDIS
  1810.     mov    cs:open_adap,ax
  1811.     sti                ; Wait for request to complete
  1812. setndmode1:
  1813.     cmp    ax,SUCCESS        ; done?
  1814.     jz    setndmode2        ; z = yes, success
  1815.     cmp    ax,REQUEST_QUEUED    ; Is it queued?
  1816.     jne    setndmode2        ; ne = no, fail
  1817.     mov    ax,cs:req_con_flg    ; get current status
  1818.     jmp    setndmode1        ; keep polling
  1819. setndmode2:
  1820.     pop    bx
  1821.     pop    es
  1822.     ret                ; NDIS return code is in AX
  1823. set_ndis_mode ENDP
  1824.  
  1825. ;
  1826. ; Put MAC entry points into static locations - called at bind time.
  1827. ;
  1828. sav_mac    PROC    NEAR
  1829.     push    ax
  1830.     les    si,mac_cctp
  1831.     mov    ax,es:[si].mod_ds    ; save MAC ds
  1832.     mov    mac_ds, ax
  1833.     les    si,es:[si].udtp
  1834.  
  1835.     mov    bx,offset Request    ; save request entry point
  1836.     mov    ax, es:4[si]
  1837.     mov    [bx],ax
  1838.     mov    ax,es:6[si]
  1839.     mov    2[bx], ax
  1840.  
  1841.     mov    bx,offset TransmitChain    ; save xmt block entry point
  1842.     mov    ax,es:8[si]
  1843.     mov    [bx],ax
  1844.     mov    ax,es:10[si]
  1845.     mov    2[bx],ax
  1846.  
  1847.     mov    bx,offset TransferData    ; save xfer data entry point
  1848.     mov    ax,es:12[si]
  1849.     mov    [bx],ax
  1850.     mov    ax,es:14[si]
  1851.     mov    2[bx],ax
  1852.  
  1853.     mov    bx,offset ReceiveRelease ; save recv rel entry point
  1854.     mov    ax,es:16[si]
  1855.     mov    [bx],ax
  1856.     mov    ax,es:18[si]
  1857.     mov    2[bx],ax
  1858.  
  1859.     mov    bx,offset IndicationOn    ; save ind on entry point
  1860.     mov    ax,es:20[si]
  1861.     mov    [bx],ax
  1862.     mov    ax,es:22[si]
  1863.     mov    2[bx],ax
  1864.  
  1865.     mov    bx,offset IndicationOff    ; save ind off entry point
  1866.     mov    ax,es:24[si]
  1867.     mov    [bx],ax
  1868.     mov    ax,es:26[si]
  1869.     mov    2[bx],ax
  1870.     pop    ax
  1871.     ret
  1872. sav_mac    ENDP
  1873.  
  1874. ; Message strings needed at bind time.
  1875.  
  1876. bad_open_adpt    db    "Adapter did not open", EOL
  1877. bad_set_pkt    db    "Set packet filter failed", EOL
  1878. vec_in_use    db    "Vector already in use", EOL
  1879. bad_bind    db    7,"BIND failed",EOL
  1880. t8023        db    '802.3',0
  1881. t8023len    equ    $-t8023
  1882. t8025        db    '802.5',0
  1883. t8025len    equ    $-t8025
  1884.  
  1885. end_res:    ;;;; Currently not keeping init code in memory
  1886.  
  1887. ;
  1888. ; DOS device driver interrupt entry point.
  1889. ;
  1890. ; This is used to initialize module and read parameters from PROTOCOLS.INI
  1891. ; only, and frees itself after startup.  The NDIS bind takes place later,
  1892. ; via dis_pat and its friends above.
  1893. ;
  1894. intr    PROC    FAR
  1895.     push    es            ; save all registers
  1896.     push    ds
  1897.     push    si
  1898.     push    di
  1899.     push    dx
  1900.     push    cx
  1901.     push    bx
  1902.     push    ax
  1903.  
  1904.     mov    ax,cs            ; check to see if already initialized
  1905.     mov    ds,ax
  1906.     mov    al,init_flg        ; our init flag
  1907.     or    al,al            ; not inited yet (0)?
  1908.     jz    intr1            ; z = yes, init now
  1909.  
  1910.     mov    bx,req_off        ; already initialized - return 
  1911.     mov    ds,req_seg        ;  with error
  1912.     mov    [bx].status, 810Ch
  1913.     jmp    rtn
  1914.  
  1915. intr1:    cli                ; not initialized - switch to new 
  1916.     mov    si,SS            ;  stack and init
  1917.     mov    dx,SP        
  1918.     mov    ax,CS
  1919.     mov    SS,ax        
  1920.     mov    SP,OFFSET new_stk    ; Need a big stack for this call
  1921.     STI                ; Critical region
  1922.     PUSH    SI            ; Save old SS
  1923.     PUSH    DX            ;  and SP
  1924.     MSG    msg_copyright        ; Display copyright notice
  1925.     call    init            ; Init this driver
  1926.  
  1927.     mov    ax,cs            ; Set DS == CS
  1928.     mov    ds,ax
  1929.     mov    bx,req_off        ; Get request header ptr
  1930.     mov    es,req_seg
  1931.     mov    word ptr es:[bx].status,0100h    ; Set return status ok
  1932.     mov    init_flg,1        ; Note that we've initialized
  1933.     mov    ax,offset end_res    ; Set end of resident code
  1934.     mov    word ptr es:[bx].end_off,ax
  1935.     mov    ax,cs
  1936.     mov    es:[bx].end_seg,ax
  1937.  
  1938.     POP    DI            ; Old SP
  1939.     POP    SI            ;  and old SS
  1940.     CLI                ; Critical region
  1941.     mov    SS, SI            ; Change back to old stack
  1942.     mov    SP, DI
  1943.     STI                ; End critical region
  1944. rtn:    pop    ax            ; All done
  1945.     pop    bx
  1946.     pop    cx
  1947.     pop    dx
  1948.     pop    di
  1949.     pop    si
  1950.     pop    ds
  1951.     pop    es
  1952.     ret
  1953. intr    ENDP
  1954.  
  1955.     db    512 dup (0)
  1956. new_stk    label    word        ; A stack for init to use
  1957.     db    4 dup (0)
  1958. fil_han    dw    0        ; File handle for init
  1959.  
  1960. ;
  1961. ; Initialize the converter module - read parameters from PROTOCOLS.INI.
  1962. ;
  1963. init    PROC    NEAR
  1964.     mov    ax,cs            ; open the Protocol Manager driver
  1965.     mov    ds,ax
  1966.     mov    ah,fopen              ; open file
  1967.     mov    al,0C2h          
  1968.     mov    dx,offset pm__nam    ; device name
  1969.     int    dos
  1970.     jnc    init1                  ; nc = success
  1971.     MSG    pro_no_open        ; error
  1972.     jmp    init_err
  1973.  
  1974. init1:    mov    fil_han,ax        ; file handle
  1975.     mov    bx, ax
  1976.     mov    ax, cs
  1977.     mov    ds, ax
  1978.     mov    drv_req.req_opc,1    ; make GetProtocolManagerInfo call
  1979.     mov    drv_req.req_sta,-1    ; zero out return status
  1980.     mov    drv_req.req_of1,-1    ; NULL out pointers
  1981.     mov    drv_req.req_sg1,-1
  1982.     mov    drv_req.req_of2,-1    ; NULL out pointer 2
  1983.     mov    drv_req.req_sg2,-1
  1984.     mov    drv_req.req_prm,-1    ; zero out parameter word
  1985.     
  1986.     mov    ah,ioctl        ; IOCTL req
  1987.     mov    al,02h            ; device input
  1988.     mov    dx,offset drv_req    ; pointer to buffer
  1989.     mov    cx,14            ; size of buffer
  1990.     int    dos            ; call DOS
  1991.     jnc      init2            ; nc = success
  1992.     MSG    pro_bad_gpm        ; Error: print msg & bomb
  1993.     jmp    init_err
  1994.  
  1995. init2:    mov    ax, cs            ; restore ds
  1996.     mov    ds, ax
  1997.  
  1998.     mov    ax,offset pro_nam    ; Get name of module to bind to,
  1999.     push    ax            ;  returned by get_pro in ES:DI
  2000.     mov    ax,pro_nam_len
  2001.     push    ax
  2002.     mov    ax,offset pro_bnd_to
  2003.     push    ax
  2004.     mov    ax,pro_bnd_to_len
  2005.     push    ax
  2006.     xor    ax,ax
  2007.     push    ax
  2008.     call    get_pro            ; Try to find the token we want
  2009.     or    di,di            ; Was it there?
  2010.     jnz    init4            ; nz = yes, parse it
  2011.     mov    drv_bnd.bnd_cnt,0    ; else say nothing bound
  2012.     jmp    short init45
  2013.  
  2014. init4:    push    ds            ; Save name in bindings structure
  2015.     push    ds            ; currently allowed to bind to only
  2016.     push    es            ;  one MAC
  2017.     pop    ds
  2018.     pop    es
  2019.     mov    si,di
  2020.     mov    di,offset drv_bnd.bnd_nam
  2021.     mov    cx,-2[si]
  2022.     cld
  2023.     rep    movsb
  2024.     pop    ds
  2025.  
  2026. init45:    mov    ax,offset pro_nam    ; Get Packet Driver vector to use
  2027.     push    ax
  2028.     mov    ax,pro_nam_len
  2029.     push    ax
  2030.     mov    ax,offset pro_prm_vec    ; "INTVEC" keyword
  2031.     push    ax
  2032.     mov    ax,pro_prm_vec_len
  2033.     push    ax
  2034.     xor    ax,ax
  2035.     push    ax
  2036.     call    get_pro            ; Go look for the token
  2037.     or    di,di            ; Was the token found?
  2038.     jnz    init5            ; nz = yes
  2039.     MSG    vec_not_spc        ; abort if not found
  2040.     jmp    init_err
  2041.  
  2042. init5:    mov    dx,es:[di]        ; check that vector is in range
  2043.     cmp    dx,80h            ; 0x80 is high limit
  2044.     jge    bad_vec2
  2045.     cmp    dx,60h            ; 0x60 is low limit
  2046.     jl    bad_vec2
  2047.     mov    pd_vector,dx        ; Save value for bind time
  2048.     jmp    short init6        ; Go on to EOI interrupt
  2049.  
  2050. bad_vec2:
  2051.     MSG    msg_bad_vec        ; Abort if out of range
  2052.     jmp    init_err
  2053.  
  2054. init6:    mov    ax,offset pro_nam    ; Get EOI interrupt (if any)
  2055.     push    ax 
  2056.     mov    ax,pro_nam_len
  2057.     push    ax
  2058.     mov    ax,offset pro_daisy_vec ; "CHAINVEC" key word
  2059.     push    ax         
  2060.     mov    ax,pro_daisy_len
  2061.     push    ax
  2062.     xor    ax,ax
  2063.     push    ax
  2064.     call    get_pro            ; Try to find the token
  2065.     or    di,di
  2066.     jz    init7            ; z = no interrupt
  2067.  
  2068.     mov    dx,es:[di]        ; Check that interrupt is ok
  2069.     cmp    dx,80h            ; High limit is 0x80
  2070.     jae    bad_vec3        ; ae = above high limit
  2071.     cmp    dx,60h            ; Low limit is 0x60
  2072.     jb    bad_vec3        ; b = below lower limit
  2073.     mov    byte ptr ind_int+1,dl    ; Modify the code
  2074.     mov    param_int, dx        ; Save interrupt number
  2075.     jmp    short init7        ; Go do the RegisterModule
  2076.  
  2077. bad_vec3:
  2078.     MSG    msg_bad_vec
  2079.     jmp    init_err        ; Abort installation
  2080.  
  2081. init7:    mov    ax,offset pro_nam    ; Get old Novell 802.3 keyword
  2082.     push    ax 
  2083.     mov    ax,pro_nam_len
  2084.     push    ax
  2085.     mov    ax,offset pro_novell    ; "NOVELL" key word
  2086.     push    ax         
  2087.     mov    ax,pro_nov_len
  2088.     push    ax
  2089.     xor    ax,ax
  2090.     push    ax
  2091.     mov    novell,0        ; assume no token
  2092.     call    get_pro            ; Try to find the token
  2093.     or    di,di
  2094.     jz    init8            ; z = no token
  2095.     mov    dx,es:[di]        ; get the token's value
  2096.     and    dl,not 20h        ; to upper case
  2097.     cmp    dl,'Y'            ; "yes"?
  2098.     jne    init8            ; ne = no conversion
  2099.     mov    novell,1        ; set flag
  2100.     MSG    novmsg            ; tell the user about conversion
  2101.  
  2102. init8:    call    pkt_ptr            ; Initialize the LDT and CCT pointers
  2103.     mov    ax,cs
  2104.     mov    ds,ax
  2105.     mov    drv_req.req_opc,2    ; RegisterModule call
  2106.     mov    drv_req.req_sta,0    ; zero out return status
  2107.     mov    drv_req.req_of1,offset drv_cct ; cct pointer
  2108.     mov    drv_req.req_sg1,ax
  2109.     mov    drv_req.req_of2,offset drv_bnd
  2110.     mov    drv_req.req_sg2,ax
  2111.     mov    drv_req.req_prm,0    ; zero out parameter word
  2112.     mov    ah,ioctl        ; IOCTL call
  2113.     mov    al,2
  2114.     mov    dx,offset drv_req
  2115.     mov    cx,14
  2116.     mov    bx,fil_han
  2117.     int    dos
  2118.     mov    ax,drv_req.req_sta    ; check return status
  2119.     cmp    ax,SUCCESS
  2120.     je    init9            ; e = success
  2121.     mov    cs:rtn_cod,ax        ; abort if reg mod failed
  2122.     MSG    reg_mod_nok
  2123.     jmp    init_err
  2124.  
  2125. init9:    mov    bx,fil_han        ; Close protman device
  2126.     mov    ah,fclose
  2127.     int    dos
  2128.     jc    init10            ; c = failure
  2129.     xor    ax,ax            ; Indicate success
  2130.     ret                ;  & do normal return
  2131.  
  2132. init10:    MSG    msg_err_clo        ; close failed, quite unlikely
  2133.     jmp    init_err
  2134.  
  2135. init_err:mov    ax,1            ; error return
  2136.     ret
  2137. init    ENDP
  2138.  
  2139. ; get_pro returns a pointer to the keyword entry from GPMI call
  2140. ;    12[bp] is a pointer to module name
  2141. ;    10[bp] is length of module name
  2142. ;    8[bp] is a pointer to keyword name
  2143. ;    6[bp] is length of keyword name
  2144. ;    4[bp] is number of parameter wanted from specified keyword
  2145. ;
  2146. ; returns
  2147. ;    es:bx is pointer to param
  2148. ;    ax zero for ok and !0 for not found
  2149. ;
  2150. get_pro    PROC    NEAR
  2151.     push    bp
  2152.     mov    bp,sp
  2153.     push    ds
  2154.     push    bx
  2155.     push    si
  2156.     lds    bx,dword ptr drv_req.req_of1    ; ConMemIma pointer
  2157.  
  2158.     mov    ax,cs                ; find module name
  2159.     mov    es,ax
  2160. getpro1:mov    ax,ds                ; quit if pointer NULL (eol)
  2161.     or    ax,ax
  2162.     jz    err_get_pro            ; z = error
  2163.     mov    di,12[bp]            ; module name
  2164.     mov    si,bx                ; set up to point name
  2165.     add    si,8
  2166.     mov    cx,10[bp]            ; module name length
  2167.     cld
  2168.     repe    cmpsb                ; right module name?
  2169.     je    pro_fnd                ; e = module name found
  2170.     lds    bx,dword ptr [bx]        ; not found-load next in chain
  2171.     jmp    short getpro1
  2172.  
  2173. pro_fnd:
  2174.     add    bx,24                ; offset of parameter pointers
  2175. getpro2:
  2176.     mov    ax,ds
  2177.     or    ax,ax
  2178.     jz    err_get_pro
  2179.     mov    di,8[bp]            ; parameter name
  2180.     mov    cx,6[bp]            ; parameter name length
  2181.     mov    si,bx
  2182.     add    si,8
  2183.     cld
  2184.     repe    cmpsb
  2185.     je    key_fnd                ; e = parameter found
  2186.     lds    bx,dword ptr [bx]        ; not found-load next in chain
  2187.     jmp    short getpro2
  2188. key_fnd:
  2189.     add    bx,24                ; offset of values
  2190.     mov    cx,4[bp]            ; check if enough values are 
  2191.     cmp    cx,[bx]                ; here
  2192.     jge    err_get_pro
  2193.     add    bx,2                ; position to the value
  2194.     jcxz    prm_fnd                ; may be either char string
  2195. getpro3:                    ;  or number depending on type
  2196.     add    bx,2
  2197.     add    bx,[bx]
  2198.     add    bx,2
  2199.     loop    getpro3
  2200. prm_fnd:
  2201.     mov    si,bx                ; set es:di to point to value
  2202.     add    si,4
  2203.     mov    cx,2[bx]
  2204.     mov    ax,ds
  2205.     mov    es,ax
  2206.     mov    di,si
  2207.     jmp    short getpro4
  2208. err_get_pro:
  2209. ;    MSG    pro_not_fnd            ; error return
  2210.     xor    ax,ax
  2211.     mov    es,ax 
  2212.     mov    di,ax
  2213. getpro4:
  2214.     pop    si                ; common return
  2215.     pop    bx
  2216.     pop    ds
  2217.     pop    bp
  2218.     ret    10
  2219. get_pro    ENDP
  2220.  
  2221.  
  2222. pkt_ptr    PROC    NEAR                ; Set up pointers in Packet 
  2223.     mov    ax,cs                ; Driver ldt and cct
  2224.     mov    ds,ax                ;  Note:most of the could 
  2225.     mov    bx,offset drv_ldt        ;  (should) be done statically
  2226.     mov    word ptr [bx],offset drv_cct    ; driver's cct back pointer
  2227.     mov    2[bx], ax
  2228.     add    bx,8                ; skip int flgs
  2229.     mov    [bx],offset req_con        ; RequestConfirm address
  2230.     mov    2[bx],ax
  2231.     mov    4[bx],offset xmt_con        ; TransmitConfirm address
  2232.     mov    6[bx],ax
  2233.     mov    8[bx],offset rcv_lah        ; ReceiveLookahead indication 
  2234.     mov    10[bx],ax
  2235.     mov    12[bx],offset ind_com        ; IndicationComplete address
  2236.     mov    14[bx],ax
  2237.     mov    16[bx],offset rcv_chn        ; ReceiveChain indication add
  2238.     mov    18[bx],ax
  2239.     mov    20[bx],offset sta_ind        ; status indication address
  2240.     mov    22[bx],ax
  2241.  
  2242.     mov    bx,offset drv_cct.ldtp        ; set up point to drv ldt
  2243.     mov    word ptr [bx],offset drv_ldt
  2244.     mov    2[bx],ax
  2245. ;
  2246. ;set up pointers in pkt driver cct
  2247. ;    only doing lower dispatch table, all other left NULL
  2248. ;    hopefully this will work
  2249. ;
  2250.     mov    drv_cct.mod_id,-1
  2251.     mov    drv_cct.mod_ds,ax
  2252.     mov    bx,offset drv_cct.system
  2253.     mov    [bx],offset dis_pat        ; drv system func entry point
  2254.     mov    2[bx],ax            ; drv ds
  2255.     mov    word ptr 16[bx],offset drv_ldt    ; ptr to ldt
  2256.     mov    18[bx],ax
  2257.     ret
  2258. pkt_ptr    ENDP
  2259.  
  2260. ; Text messages that can be flushed after startup but before bind.
  2261.  
  2262. msg_no_vect    db    "Vector not specified", EOL
  2263. msg_bad_vec    db    "Invalid vector (must be 60h-7Fh)",EOL
  2264. msg_err_clo    db    "Error closing MAC driver", EOL
  2265. msg_copyright    db     "MAC/DIS to Packet Driver converter loaded."
  2266.         db    " Version 1.09",CR,LF
  2267.         db     "Copyright 1991 FTP Software, Inc.  All rights "
  2268.         db    "reserved.", cr,lf
  2269.         db    " v1.07 by Joe R. Doupnik, jrd@cc.usu.edu, "
  2270.         db    "Utah State Univ, 18 May 1991", cr,lf
  2271.         db    " v1.08 by Dan Lanciani, ddl@harvard.harvard.edu",cr,lf
  2272.         db    " v1.09 by Joe R. Doupnik, jrd@cc.usu.edu, "
  2273.         db    "Utah State Univ, 3 Nov 1991",EOL
  2274. pm__nam        db    "protman$", 0
  2275. pro_no_open    db    "Protocol Manager not present", EOL
  2276. pro_bad_gpm    db    "GetProtocolManagerInfo call failed", EOL
  2277. pro_nam        db    "PKTDRV",0
  2278. pro_nam_len    equ    $ - pro_nam
  2279. pro_prm_vec    db    "INTVEC",0
  2280. pro_prm_vec_len    equ    $ - pro_prm_vec 
  2281. pro_daisy_vec    db    "CHAINVEC",0
  2282. pro_daisy_len    equ    $ - pro_daisy_vec 
  2283. pro_prm_nok    db    "SINTVECXX",0
  2284. pro_prm_nok_len    equ    $ - pro_prm_nok
  2285. pro_bnd_to    db    "BINDINGS",0
  2286. pro_bnd_to_len    equ    $ - pro_bnd_to
  2287. pro_novell    db    "NOVELL",0
  2288. pro_nov_len    equ    $ - pro_novell
  2289. novmsg        db    "Using OLD NOVELL 802.3 packets on the wire",EOL
  2290. vec_not_spc    db    "Interrupt vector for Packet Driver not specifed"
  2291.         db    " in PROTOCOL.INI", EOL
  2292. reg_mod_nok    db    "Register module call failed", EOL
  2293. CSEG    ends
  2294.     end
  2295.